XSLT每n个节点使用一个过滤器

Question

我正在使用XSLT进行一些输出格式化，我希望在输出的每N个节点周围都有一个包装器元素。我读过xslt-添加<tr>lt；tr>每n个节点？，但我的问题是源节点必须来自查找：

<xsl:for-each select="key('items-by-product', $productid)">

而不仅仅是模板匹配。我发现的所有例子都假设你想要的节点都紧挨着，它们只是在计算兄弟节点。

我有一个适合我的解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
  <xsl:variable name='num_per_div' select='2' />
  <xsl:variable name='productid' select='1' />
  <xsl:output method="xml" indent="yes"/>
  <xsl:key name="items-by-product" match="item" use="productid"/>
  <xsl:template match="data">
    <output>
      <xsl:for-each select="key('items-by-product', $productid)">
        <xsl:variable name='pos' select='position()' />
        <xsl:if test="position() = 1 or not((position()-1) mod $num_per_div)">
          <outer pos="{$pos}">
            <xsl:for-each select="key('items-by-product', $productid)">
              <xsl:variable name='ipos' select='position()' />
              <xsl:if test="$ipos >= $pos and $ipos &lt; $pos + $num_per_div">
                <inner>
                  <xsl:value-of select="itemid"/>
                </inner>
              </xsl:if>
            </xsl:for-each>
          </outer>
        </xsl:if>
      </xsl:for-each>      
    </output>
  </xsl:template>
</xsl:stylesheet>

带数据

<data>
  <item>
    <productid>1</productid>
    <itemid>1</itemid>
  </item>
  <item>
    <productid>1</productid>
    <itemid>2</itemid>
  </item>
  <item>
    <productid>2</productid>
    <itemid>A</itemid>
  </item>
  <item>
    <productid>1</productid>
    <itemid>3</itemid>
  </item>
  <item>
    <productid>2</productid>
    <itemid>B</itemid>
  </item>
  <item>
    <productid>1</productid>
    <itemid>4</itemid>
  </item>
</data>

它产生

<?xml version="1.0" encoding="utf-8"?>
<output>
  <outer pos="1">
    <inner>1</inner>
    <inner>2</inner>
  </outer>
  <outer pos="3">
    <inner>3</inner>
    <inner>4</inner>
  </outer>
</output>

但这是在每个节点的所有节点中循环，这让我觉得效率很低。

有没有更好的方法可以更有效地产生相同的产出？以下同级技术可以与过滤器一起使用吗？

Answer 1

您可以使用带有position() mod $num_per_div的外循环来获得每个块的一次"迭代"，然后在其中根据位置从整个key(...)节点中选择该块的成员：

<xsl:for-each select="key('items-by-product', $productid)
                       [position() mod $num_per_div = 1]">
  <xsl:variable name="iter" select="position()" />
  <xsl:variable name="first" select="($iter - 1) * $num_per_div + 1" />
  <xsl:variable name="last" select="$iter * $num_per_div" />
  <outer pos="{$first}">
    <xsl:for-each select="key('items-by-product', $productid)
                           [position() &gt;= $first and position() &lt;= $last]">
      <inner><xsl:value-of select="itemid"/></inner>
    </xsl:for-each>
  </outer>
</xsl:for-each>

这里的关键是要记住，position()函数是上下文敏感的，在不同的时间意味着不同的事情。在$iter变量的定义中，当前节点列表是外部为每个节点选择的节点，即具有键返回的第一、第三、第五等项目的列表（因此position()表示块编号）。但是，在内部的select上的谓词中，对于每个，当前节点列表是从key函数调用返回的所有节点（因此position()是在给定productid的所有节点列表中测试的节点的位置）。

Answer 2

您可以从将感兴趣的节点复制到变量中开始；这将使他们——而且只有他们——成为兄弟姐妹。然而，在XSLT1.0中，这样的变量将包含结果树片段，需要将其转换为节点集才能进行进一步处理：

XSLT 1.0

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:key name="items-by-product" match="item" use="productid"/>
<xsl:variable name="groupSize" select="2" />
<xsl:variable name="productid" select="1" />
<xsl:variable name="my-items">
    <xsl:copy-of select="key('items-by-product', $productid)"/>
</xsl:variable>
<xsl:template match="/">
    <output>
        <xsl:for-each select="exsl:node-set($my-items)/item[position() mod $groupSize = 1]">
            <outer pos="{position()}">
                <xsl:for-each select=". | following-sibling::item[position() &lt; $groupSize]" >
                    <inner>
                        <xsl:value-of select="itemid"/>
                    </inner>
                </xsl:for-each>
            </outer>
        </xsl:for-each>
    </output>
</xsl:template>
</xsl:stylesheet>