流涎事件序列具有累积功能

Question

我想为以下用例构建规则:我期待两个"AddToCart"事件，然后"搜索"事件，完全按照所描述的顺序。注:这不是一个真正的业务用例。

目前，我正试图通过以下规则实现解决方案:

rule "Rule-102"
salience 1000110000
    agenda-group "level0"
    dialect "mvel"
    when
         Number(doubleValue >= 2) from accumulate ($event1: Event(eval($event1.getName().equals('AddToCart'))),count($event1));$event: Event()
         $event2: Event(eval($event2.getName().equals('Search')), this after $event)
    then
        sendEvent($event2, ed, drools);
end

该规则不能正确工作，因为事件顺序没有正确定义:Search -> AddToShoppingCart -> AddToShoppingCart = Action

我只想要严格的顺序:AddToShoppingCart -> AddToShoppingCart -> Search = Action

Answer 1

如果您的规则包含一组模式(在本例中为2个AddToCart和1个Search)，您可以尝试这样做:

rule "Rule-102"
when
    $e1: Event(name == "AddToCart")
    $e2: Event(name == "AddToCart", timestamp > $e1.timestamp)
    $s1: Event(name == "Search", timestamp > $e2.timestamp)
then
    sendEvent($s1, ed, drools);
end

尽管很优雅，但这个解决方案有一些潜在的问题:

• 如果你想使用更多的AddToCart事件，它将无法很好地扩展。
• 如果您有3个(或更多)AddToCart事件，此规则将多次触发(我不确定这是否是您用例中所需的行为)

如果您想使用更通用的方法，您可以尝试以下内容:

rule "Rule-102"
when
    $s1: Event(name == "Search")
    Number(intValue >= 2) from accumulate(
        Event(name == "AddToCart", timestamp < $s1.timestamp),
        count(1)
    )
then
    sendEvent($s1, ed, drools);
end

希望有帮助，