如何在GLSL/WebGL中将一个32位整数打包为4.8位整数

Question

我希望将一些复杂的数学并行化，WebGL看起来是实现这一点的完美方法。问题是，您只能从纹理中读取8位整数。理想情况下，我希望从纹理中获得32位数字。我想到了使用4个颜色通道来获得每个像素32位，而不是8位的4倍。

我的问题是，GLSL没有"%"运算符或任何位运算符！

TLDR：如何使用glsl中的运算符将32位数字转换为48位数字。

关于该技术的一些额外信息（使用逐位运算符）：

如何将一个64位整数存储在两个32位整数中，并再次转换回

Answer 1

您可以通过乘以/除以2的幂来进行位移。

正如评论中所指出的，我最初发布的方法是有效的，但不正确，这是Aras Pranckevičius的一个，注意帖子中的源代码本身包含一个拼写错误，是HLSL，这是一个GLSL端口，拼写错误已更正：

const vec4 bitEnc = vec4(1.,255.,65025.,16581375.);
const vec4 bitDec = 1./bitEnc;
vec4 EncodeFloatRGBA (float v) {
    vec4 enc = bitEnc * v;
    enc = fract(enc);
    enc -= enc.yzww * vec2(1./255., 0.).xxxy;
    return enc;
}
float DecodeFloatRGBA (vec4 v) {
    return dot(v, bitDec);
}

Answer 2

通常，如果要将浮点数的有效数字打包为字节，则必须连续提取有效数字的8位包，并将其存储在一个字节中。

对预定义范围内的浮点数字进行编码

为了将浮点值打包到4*8位缓冲区中，必须首先指定源值的范围
如果定义了值范围[minVal，maxVal]，则必须将其映射到范围[0.0，1.0]:

float mapVal = clamp((value-minVal)/(maxVal-minVal), 0.0, 1.0);

函数Encode将[0.0，1.0]范围内的浮点值打包为vec4:

vec4 Encode( in float value )
{
    value *= (256.0*256.0*256.0 - 1.0) / (256.0*256.0*256.0);
    vec4 encode = fract( value * vec4(1.0, 256.0, 256.0*256.0, 256.0*256.0*256.0) );
    return vec4( encode.xyz - encode.yzw / 256.0, encode.w ) + 1.0/512.0;
}

函数Decode从vec4:中提取[0.0，1.0]范围内的浮点值

float Decode( in vec4 pack )
{
    float value = dot( pack, 1.0 / vec4(1.0, 256.0, 256.0*256.0, 256.0*256.0*256.0) );
    return value * (256.0*256.0*256.0) / (256.0*256.0*256.0 - 1.0);
}

以下函数在[minVal，maxVal]范围内打包并提取浮点值：

vec4 EncodeRange( in float value, flaot minVal, maxVal )
{
    value = clamp( (value-minVal) / (maxVal-minVal), 0.0, 1.0 );
    value *= (256.0*256.0*256.0 - 1.0) / (256.0*256.0*256.0);
    vec4 encode = fract( value * vec4(1.0, 256.0, 256.0*256.0, 256.0*256.0*256.0) );
    return vec4( encode.xyz - encode.yzw / 256.0, encode.w ) + 1.0/512.0;
}
float DecodeRange( in vec4 pack, flaot minVal, maxVal )
{
    value = dot( pack, 1.0 / vec4(1.0, 256.0, 256.0*256.0, 256.0*256.0*256.0) );
    value *= (256.0*256.0*256.0) / (256.0*256.0*256.0 - 1.0);
    return mix( minVal, maxVal, value );
}

用指数对浮点数字进行编码

另一种可能性是将有效数字编码为RGB值的3*8位，并将指数编码为alpha通道的8位：

vec4 EncodeExp( in float value )
{
    int exponent  = int( log2( abs( value ) ) + 1.0 );
    value        /= exp2( float( exponent ) );
    value         = (value + 1.0) * (256.0*256.0*256.0 - 1.0) / (2.0*256.0*256.0*256.0);
    vec4 encode   = fract( value * vec4(1.0, 256.0, 256.0*256.0, 256.0*256.0*256.0) );
    return vec4( encode.xyz - encode.yzw / 256.0 + 1.0/512.0, (float(exponent) + 127.5) / 256.0 );
}
float DecodeExp( in vec4 pack )
{
    int exponent = int( pack.w * 256.0 - 127.0 );
    float value  = dot( pack.xyz, 1.0 / vec3(1.0, 256.0, 256.0*256.0) );
    value        = value * (2.0*256.0*256.0*256.0) / (256.0*256.0*256.0 - 1.0) - 1.0;
    return value * exp2( float(exponent) );
}

注意，由于标准的32位IEEE 754数字只有24个有效数字，因此将该数字编码为3个字节是完全足够的。

_{另请参阅如何在float和vec4、vec3、vec2之间转换？}

Answer 3

每个人在WebGl中如何处理这样的事情都是绝对正确的，但我想分享一个获取值的技巧。

假设你想对两个适合16位的值进行比较：

// Generate a list of random 16bit integers
let data16bit = new Uint16Array(1000000);
for(let i=0; i < data16bit.length; i+=2){
    data16bit[i]   = Math.random()*(2**16);
    data16bit[i+1] = Math.random()*(2**16);
}
// Read them one byte at a time, for writing to 
// WebGL
let texture = new Uint8Array(data16bit.buffer);

现在，当您在片段着色器中获得值时，您可以拾取数字进行操作：

vec4 here = texture2D(u_image, v_texCoord);
// Read the "red" byte and the "green" byte together (as a single thing) 
// as well as the "blue" byte and the "alpha" byte together as a single
// thing
vec2 a = here.rg;
vec2 b = here.ba;
// now compare the things
if(a == b){
    here.a = 1;
}
else{
    here.a = 0;
}
// return the boolean value
gl_FragColor = here;

这一点只是提醒您，您可以将相同的JavaScript内存块视为不同的大小：Uint16Array和Uint8Array（而不是试图进行移位和分解）。

更新

为了响应更多详细信息的请求，该代码非常接近于直接从该代码和解释中剪切/粘贴。

它的确切用途可以在GitLab上的相应样本（同一文件的两个部分）