使用 VBA 为 Google 日历 API v3 构建 JSON

Question

我正在尝试使用Google API V3将事件添加到Google日历中。我没有使用任何谷歌的库，所以我对如何做到这一点感到非常困惑。Google 的文档告诉我，我需要在请求正文中发送"事件资源"。我想我已经构建了一个有效的 JSON"字符串"，但我不知道如何正确准备它并在所谓的"请求正文"中发送它。让我感到困惑的是字符串值用引号括起来而非字符串值不是的方式。这是否意味着我需要将整个事情包装为字符串和双引号/四引号每个双引号？

这是我写的JSON，但我还没有弄清楚如何将其传递给Google，所以我无法对其进行测试：

{
  "kind": "calendar#event",
  "start": {
    "dateTime": 04/10/2012 08:00 AM
  },
  "end": {
    "dateTime": 04/10/2012 08:00 AM
  },
  "attendees": [
    {
      "email": "[e-mail]",
      "displayName": "My Name",
      "organizer": True,
      "self": True
    }
  ],
  "reminders": {
    "useDefault": True
  }
}

我确实在我的访问/VBA数据库中安装了一个VBJSON代码模块。我在那里看到一个名为StringToJSON的函数，它返回一个字符串。我仍然感到困惑。当我把这个JSON传递给谷歌时，它仅仅是我的代码中的一个大字符串值吗？

Answer 1

好的，所以我终于想出了如何构建和传递我的 JSON 字符串。我正在使用 VBJSON 来构建 JSON 字符串。请记住，JSON区分大小写（或者至少Google将其解释为区分大小写）。具有密钥日期时间的对与具有密钥日期时间的配对不同，Google 将拒绝后者。

'Code to create JSON using Dictionary Objects and Collection Objects
Dim d As New Scripting.Dictionary
Dim c As New Collection
d.Add "kind", "calendar#event"
d.Add "summary", "Event Title/Summary"
Dim d2(4) As New Scripting.Dictionary
d2(0).Add "dateTime", "2012-04-14T16:00:00.000-04:00"
d.Add "start", d2(0)
d2(1).Add "dateTime", "2012-04-14T18:00:00.000-04:00"
d.Add "end", d2(1)
'First Attendee
d2(2).Add "email", "[e-mail]"
d2(2).Add "displayName", "John Doe"
d2(2).Add "organizer", True
d2(2).Add "self", True
'Add attendee to collection
c.Add d2(2)
'Second attendee
d2(3).Add "email", "[e-mail]"
d2(3).Add "displayName", "Suzy Doe"
'Add attendee to collection
c.Add d2(3)
'Add collection to original/primary dictionary object
d.Add "attendees", c
'Add more nested pairs to original/primary dictionary object
d2(4).Add "useDefault", True
d.Add "reminders", d2(4)
'Now output the JSON/results
'This requires the VBJSON module (named just JSON, a module, not a class module)
Debug.Print JSON.JSONToString(d)

未经修饰的输出是这样的：

{"kind":"calendar#event","summary":"Event Title/Summary","start":{"dateTime":"2012-04-14T16:00:00.000-04:00"},"end":{"dateTime":"2012-04-14T18:00:00.000-04:00"},"attendees":[{"email":"[e-mail]","displayName":"John Doe","organizer":true,"self":true},{"email":"[e-mail]","displayName":"Suzy Doe"}],"reminders":{"useDefault":true}}

然后，以下是如何使用Google Calendar API的V3将其提交给Google。在 V3 中，必须使用 OAuth2.0，因此需要具有有效的访问令牌才能附加到 URL，如下所示。您还需要知道您的日历ID，通常是您的电子邮件地址URL编码。例如，您的日历 ID 将如下所示：john.doe%40gmail.com

Dim objXMLHTTP As MSXML2.ServerXMLHTTP
Set objXMLHTTP = New MSXML2.ServerXMLHTTP
Dim sPostData As String
sPostData = JSON.JSONToString(d)
Dim sURL As String
sURL = "https://www.googleapis.com/calendar/v3/calendars/{mycalendarid}/events?sendNotifications=false&fields=etag%2ChtmlLink%2Cid&pp=1&access_token={my oauth2.0 access token}"
With objXMLHTTP
    .Open "POST", sURL, False
    .setRequestHeader "Content-Type", "application/json"
    .Send (sPostData)
End With
Debug.Print objXMLHTTP.ResponseText
Set objXMLHTTP = Nothing