XSLT1.0贪婪背包分组方法

Question

我有一个XML数据集（从SharePoint 2007提供给DVWP），其结构类似于：

<Rows>
  <Row ID="1" Spanoffset="0" Span="55" Spantail="55"/>
  <Row ID="2" Spanoffset="30" Span="31" Spantail="61"/>
  <Row ID="3" Spanoffset="61" Span="20" Spantail="81"/>
  <Row ID="4" Spanoffset="82" Span="30" Spantail="112"/>
</Rows>

假设每一行代表一个从@Spanoffset开始、宽度为@Span的条，@Spantail就在那里，所以如果需要的话，我不必计算它。我正在努力有效地将行打包在一起，这样不会重叠的行就可以分组在一起。数据集按@Spanoffset进行预排序。这本质上是一个背包问题，因为每一行可以容纳多个可能的组。我想做的是一个简单的贪婪解决方案，我知道如何用c#或java来编码它，但由于我不能将节点标记为已访问（我可以，但当我回到递归树时会丢失它），而且我似乎无法在访问节点时删除节点，我不知道如何处理它。

例如，上面的数据看起来像这样：

<div style="clear:both">
  <div style="width: 110px; margin-left: 0px; float:left;">1</div>
  <div style="width: 40px; margin-left: 12px; float:left;">3</div>
  <div style="width: 60px; margin-left: 2px; float:left;">4</div>
</div>
<div style="clear:both">
  <div style="width: 62px; margin-left: 60px; float:left;">2</div>
</div>

我还没有试着让float正常工作，因为我还不能让Row节点按正确的顺序每个只出现一次。一旦我把它们放在那里，我就相当确定我可以把格式设置好。

到目前为止，我提出的最好的XSLT是：

<xsl:template match="row">
  <xsl:variable name="tail" select="@Spantail"/>
  <div style="width:{2*@Span}px;
    left:{2*(@Spanoffset)}px;">
    <xsl:value-of select="@ID"/>
  </div>                        
  <xsl:apply-templates select="(following-sibling::row)[@Spanoffset>=$tail][1]"/>
</xsl:template>

哪个生成

<div style="width: 110px;left: 0px">1</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 62px; left: 60px">2</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 60px; left: 164px">4</div>

所以我的问题是2（我看到的），我认为它们是交织在一起的。1） 如何修复/重新因子我的模板，使其每行只发出一次。和2） 如何将分组包装在容器<div>元素中。

两天来我一直在想这个，有人能帮上忙吗？

编辑：好吧，经过一段时间的睡眠，我通过在模板中添加一个布尔参数，并使用一些CDATA标记在为true时发出<div>标记，获得了包装容器。布尔值默认为true，当我调用嵌套的应用模板时，我将其设置为false，从而将组封装在容器中。我仍然看不到将<Row>标记为已访问的方法。

Answer 1

我认为仅使用核心XSLT非常棘手，但使用node-set（）（一个XSLT扩展函数）会更容易：

<xsl:template name="add-row">
    <xsl:param name="row"/>
    <xsl:param name="prev-group" />
    <xsl:if test="$row and not($row/@ID = $prev-group/Row/@ID)">
        <xsl:copy-of select="$row" />
        <xsl:call-template name="add-row">
            <xsl:with-param name="row" select="$row/following-sibling::Row[@Spanoffset &gt; $row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="$prev-group" />
        </xsl:call-template>
    </xsl:if>   
</xsl:template>
<xsl:template name="add-group">
    <xsl:param name="first-row" />
    <xsl:param name="prev-group" select="exsl:node-set(/)" />
    <xsl:if test="$first-row">
        <xsl:variable name="group">
            <xsl:call-template name="add-row">
                <xsl:with-param name="row" select="$first-row" />
                <xsl:with-param name="prev-group" select="$prev-group" />
            </xsl:call-template>
        </xsl:variable>
        <div clear="both">
            <xsl:for-each select="exsl:node-set($group)/Row">
                <div style="width: {2*@Span}px; left: {2*@Spanoffset}px"><xsl:value-of select="@ID"/></div>                             
            </xsl:for-each>
        </div>
        <xsl:call-template name="add-group">
            <xsl:with-param name="first-row" select="$first-row/following-sibling::Row[@Spanoffset &lt; preceding-sibling::Row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="exsl:node-set($group)" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>
<xsl:template match="Rows">
    <xsl:call-template name="add-group">
        <xsl:with-param name="first-row" select="Row[1]" />
    </xsl:call-template>
</xsl:template>

不要忘记在样式表标记中声明扩展前缀和名称空间：

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  extension-element-prefixes="exsl"
  xmlns:exsl="http://exslt.org/common">

http://exslt.org/common是Java XSLT处理器（如Xalan或Saxon）的有效命名空间；如果您使用的是MSXML，请改用urn:schemas-microsoft.com.xslt。