如何使一个单元格值依赖于多个单元格 (>2)

Question

>我有一个固定的值，在表格中一行的末尾，假设9,000。我希望这个值 9,000 取决于在 9,000 值之前的三个单元格(与 9,000 值在同一行(中输入是或否。

例如：

if YES to question 1, then multiply 9,000 by .05, call this new value `x` 
if NO to question 1, then multiply 9,000 by 1. call this new value `x` 
if YES to question 2, then multiply x by .1, call this new value `x_2` 
if NO to question 2, then multiply x by 1, call this new value `x_2` 
if YES to question 3, then multiply x_2 by .075, call this new value `x_3` 
if NO to question 3, then multiply x_2 by 1, call this new value `x_3`

我尝试使用以下 if 语句：

假设单元格 D1=9,000

=IF(A1="YES",D1*.05,
     IF(A1="NO",D1,
         IF(A2="YES",D1*.1,
             IF(A2="NO",D1,
                 IF(A3="YES",D1*.075,
                     IF(A3="NO",D1,"")
                   )
               )
           )
       )
   )

我的问题是，一旦输入了"是"的答案，9,000 的值就会变为新值。

输入另一个"是"后，值 9,000 将再次更改。

但是，我希望从第一个"是"获得的新值是受第二个和/或第三个"是"影响的值。

Answer 1

你应该尝试简化你的问题

在这里你可以看到你将得到的结果将是这样的 A*B*C*D ，具有：
A= 9000
B= 0.05 (如果 Q1= YES (， B= 1 (如果 Q1= NO (
C= 0.1 (如果 Q2= YES (， C=1 (如果 Q2= NO (
D= 0.075 (如果 Q3= YES (， D=1 (如果 Q3= FALSE (

因此，我们可以通过以下方式更改您的公式：

=D1 * IF(A1="YES",0.05,1) * IF(A2="YES",0.1,1) * IF(A3="YES",0.075,1)

(假设，根据你给出的例子，D1是9000，A1是问题1的答案，A2是问题2的答案，A3是问题3的答案(

如果您希望在答案既不YES也不NO时发生特殊情况(例如，如果有人回答了问题中的TEST(，您可以使用一些检查条件注册所有内容，例如：

=IF(AND( OR(A1="YES",A1="NO"), OR(A2="YES",A2="NO"), OR(A3="YES",A3="NO") ), 
    D1 * IF(A1="YES",0.05,1) * IF(A2="YES",0.1,1) * IF(A3="YES",0.075,1), 
    "Please answer YES or NO to the questions")