如果数据段不为零，则保护模式将失败

Question

在处理一个非常简单的引导加载程序时，我发现在进入保护模式之前为数据段（ds）分配一些东西会产生处理器故障。

这段代码工作得很好：

[BITS 16]
[ORG 0x7c00]
xor ax,ax
mov ds,ax
cli
lgdt [gdt_descriptor]  
mov  eax, cr0       
or eax,1              
mov  cr0, eax
jmp CODE_SEG:now
[BITS 32]
now:
    jmp $
    db 0
gdt_start:
gdt_null:
    dd 0x0
    dd 0x0
gdt_cs:
    dw 0xFFFF ; Limit
    dw 0x0000 ; Base
    db 0x0000    ; Base 23:16
    db 10011011b
    db 11011111b
    db 0x0000
gdt_ds:
    dw 0xFFFF ; Limit
    dw 0x0000 ; Base
    db 0x0000    ; Base 23:16
    db 10010011b
    db 11011111b
    db 0x0000
gdt_end
gdt_descriptor:
    dw gdt_end - gdt_start - 1
    dd gdt_start
CODE_SEG equ gdt_cs - gdt_start
DATA_SEG equ gdt_ds - gdt_start
times 510-($-$$) db 0  ; fill sector w/ 0's
db 0x55          ; req'd by some BIOSes
db 0xAA

这会使处理器重新启动：

[BITS 16]
[ORG 0x7c00]
mov ax,0x10 ;<-- Pre-assigning data segment
mov ds,ax
cli
lgdt [gdt_descriptor]  
mov  eax, cr0       
or eax,1              
mov  cr0, eax
jmp CODE_SEG:now
[BITS 32]
now:
    jmp $
    db 0
gdt_start:
gdt_null:
    dd 0x0
    dd 0x0
gdt_cs:
    dw 0xFFFF ; Limit
    dw 0x0000 ; Base
    db 0x0000    ; Base 23:16
    db 10011011b
    db 11011111b
    db 0x0000
gdt_ds:
    dw 0xFFFF ; Limit
    dw 0x0000 ; Base
    db 0x0000    ; Base 23:16
    db 10010011b
    db 11011111b
    db 0x0000
gdt_end
gdt_descriptor:
    dw gdt_end - gdt_start - 1
    dd gdt_start
CODE_SEG equ gdt_cs - gdt_start
DATA_SEG equ gdt_ds - gdt_start
times 510-($-$$) db 0  ; fill sector w/ 0's
db 0x55          ; req'd by some BIOSes
db 0xAA

我用NASM编译了它，然后用VMWARE运行它。

为什么会这样？

Answer 1

问题不在于您在进入保护模式之前设置了ds。问题是您在执行lgdt指令之前设置了ds。

lgdt指令还访问数据段中的内存，因此ds执行时需要是一个正确的值。更改ds 时，更改了尝试加载的 GDT 的有效地址。然后，当您进入保护模式时，该 GDT 中的cs段，GDT 条目是虚假的，并且处理器生成了异常。最后，由于您尚未设置 IDT，处理器出现双重故障，然后出现三重故障并重新启动。

假设gdt_descriptor是代码中的0x40字节，这意味着加载引导加载程序时它处于0000:7C40。 当ds为零（您的第一个示例）时，lgdt [gdt_descriptor]指令将尝试从(0x0 << 4) + 0x7C40 == 0x7C40的基准/极限加载GDT。 但是，当您将ds设置为 0x10 时，您现在正在尝试从基数/限制加载 GDT，(0x10 << 4) + 0x7C40 == 0x7D40这不是您想要的。

因此，您可以在进入保护模式之前将ds设置为0x10 - 只是不要进行任何内存访问（即 lgdt ）直到你跳进 PM 之后。