使用自定义样式(delphi)在画布上绘制一条线

Question

我需要在画布上画一些线条，但是我需要使用自定义样式，没有标准样式作为实心，点，...

例如，我需要画一条线作为"__.__ ._" 或 "。_ ._ ._ ._".我所有的线都是破折号和点的混合，我还需要设置破折号长度和破折号，点宽度。

我不想使用 GDI+ 或其他外部库...

有没有简单的方法可以做到这一点？

Answer 1

您可以使用普通 GDI 执行此操作：

procedure TForm1.FormPaint(Sender: TObject);
const
  pattern: array[0..3] of cardinal = (10, 1, 1, 1);
var
  lb: TLogBrush;
  pen, oldpen: HPEN;
begin
  lb.lbStyle := BS_SOLID;
  lb.lbColor := RGB(255, 0, 0);
  pen := ExtCreatePen(PS_COSMETIC or PS_USERSTYLE, 1, lb, length(pattern), @pattern);
  if pen <> 0 then
    try
      oldpen := SelectObject(Canvas.Handle, pen);
      Canvas.MoveTo(0, 0);
      Canvas.LineTo(ClientWidth, ClientHeight);
      SelectObject(Canvas.Handle, oldpen);
    finally
      DeleteObject(pen);
    end;
end;

Answer 2

你也可以使用 LineDDA API。当然，笔样式（如Andreas Rejbrand建议的那样）要快得多，但是LineDDA将允许您用不同的颜色绘制线条的各个部分。

var
  DottedLineDrawCounter: Integer;
procedure DDAProc(AX, AY: Integer; ACanvas: TCanvas); stdcall;
begin
  if DottedLineDrawCounter mod 4 = 0 then
    ACanvas.Pixels[AX, AY] := clRed
  else
    ACanvas.Pixels[AX, AY] := clBlack;
  Inc(DottedLineDrawCounter);
end;
...
begin
  // Usage
  DottedLineDrawCounter := 0;
  LineDDA(X1, Y1, X2, Y2, @DDAProc, LPARAM(Canvas));
end;