带有递归 Elixir 的 npm 包的 Getall 依赖项

Question

我有这个网址@registry "http://registry.npmjs.org/"当你附加包名并/latest它时，它会返回有关包的一些详细信息，我需要获取它的所有依赖项，我做了它并且它工作正常，但我需要更深入地使用它

。 如。

如果您检查http://registry.npmjs.org/handlebars/latest并且它有 4 个依赖项，我希望这些deps以及进一步了解这些neo-async以及其他deps和这些deps deps，以获取它们的依赖项。我试过这个。

defmodule Deep do
  @registry "http://registry.npmjs.org/"
  alias HTTPoison.Response, as: Resp
  def go(package, complete_deps \ []) do
    HTTPoison.get(@registry <> package <> "/latest")
    |> handle_response()
    |> get_deps()
  end
  defp get_deps(nil),  do: []
  defp get_deps(deps),  do: Enum.map(deps, fn({k, _v}) -> k end)
  defp handle_response({:ok, %Resp{status_code: 200, body: body}}), do:
    Poison.decode!(body)["dependencies"]
  defp handle_response(_), do: nil
end

但我最终还是在第一级，我试过了

get_deps结果做头和尾，更进一步与 deps，但我不知道我可以在哪里保存尾巴或所有 deps。

基本上，我想使用递归在一个列表中获取车把、deps 及其所有 deps 的 deps，我可以看到 Enum.map 的解决方案，但它会有点丑陋。任何帮助将不胜感激

Answer 1

以下代码将生成依赖关系树。

它依赖于jason Elixir软件包，并使用Erlang标准库中附带httpc HTTP客户端。使用这些与使用 poison 和 httpoison 相比，具有将代码依赖项的数量从 8 个减少到 1 个的优点：

defmodule Deep do
  @registry 'http://registry.npmjs.org/'
  def go([]), do: []
  def go([dep | other_deps]), do: [go(dep) | go(other_deps)]
  def go(package) do
    deps =
      [@registry, to_charlist(package), '/latest']
      |> :httpc.request()
      |> handle_response()
      |> get_deps()
    if Enum.empty?(deps), do: package, else: {package, go(deps)}
  end
  defp get_deps(nil), do: []
  defp get_deps(deps), do: Map.keys(deps)
  defp handle_response({:ok, {{_, 200, _}, _headers, body}}),
    do: Jason.decode!(body)["dependencies"]
  defp handle_response(_), do: nil
end

输出：

iex(1)> Deep.go("handlebars")
{"handlebars",
 [
   "neo-async",
   {"optimist", ["minimist", "wordwrap"]},
   "source-map",
   {"uglify-js", ["commander", "source-map"]}
 ]}
iex(2)>

Answer 2

在一个平面列表中获取所有唯一的依赖项：

defmodule Deep do
  @registry "http://registry.npmjs.org/"
  alias HTTPoison.Response, as: Resp
  def go(package) do
    HTTPoison.get(@registry <> package <> "/latest")
    |> handle_response()
    |> get_deps()
    |> List.flatten()
    |> Enum.uniq()
  end
  defp get_deps(nil),  do: []
  defp get_deps(deps),  do: Enum.map(deps, fn({k, _v}) -> [k | go(k)] end)
  defp handle_response({:ok, %Resp{status_code: 200, body: body}}), do:
    Poison.decode!(body)["dependencies"]
  defp handle_response(_), do: nil
end

用法：

iex(11)> Deep.go("handlebars")             
["neo-async", "optimist", "minimist", "wordwrap", "source-map", "uglify-js",
 "commander"]