Haskell中的旋转参数

Question

Haskell中的flip函数用于切换函数的前两个参数的位置:

flip :: (a -> b -> c) -> b -> a -> c
flip f y x = f x y

类似地，我们可以编写一个函数来旋转三个参数:

rot :: (a -> b -> c -> d) -> b -> c -> a -> d
rot f y z x = f x y z

这个概念可以扩展到包含任意数量参数的函数吗?

给定一个a -> ... -> z类型的函数，是否有可能写出如下类型的函数?

(a -> ... -> z) -> ... -> a -> z

我知道->运算符是右结合的。因此... -> z不能分裂。尽管如此，我还是想确切地知道。

Answer 1

你说得对，你不能这么做。你必须对任意数量的参数进行模式匹配，而这是无法做到的。

你可以使用Template Haskell为不同的属性生成一组旋转函数，但是你必须事先决定要生成多少，并且它不会是一个真正的通用函数，只是一个编写它们的快捷方式。

如果你的函数碰巧把它们的参数作为列表(eew)，你也可以做类似的事情，但这也有一个明显的缺点，要求参数类型是同质的。

Answer 2

从技术上讲，rot可以(但可能不应该)使用IncoherentInstances扩展实现:

{-# LANGUAGE MultiParamTypeClasses, TypeFamilies,
  FlexibleInstances, FlexibleContexts,
  UndecidableInstances, IncoherentInstances #-}    
class Rotable a r where
    rot :: a -> r
instance (r ~ (b -> a -> c)) => Rotable (a -> b -> c) r where
    rot = flip
instance (Rotable (a -> c -> d) r', r ~ (b -> r')) => Rotable (a -> b -> c -> d) r where
    rot f b = rot (`f` b)

用法示例:

*Main> rot (-) 1 2
1
*Main> :t rot foldr
rot foldr :: b -> [a] -> (a -> b -> b) -> b
*Main> :t (rot . rot) foldr
(rot . rot) foldr :: [a] -> (a -> b -> b) -> b -> b
*Main> (rot . rot) foldr [1..5] (+) 0
15