在f#中使用布尔函数作为模式鉴别器

Question

我试着在谷歌上搜索了一下，但我找不到一组指导我想做什么的词。

我正在尝试解决欧拉项目第54题，我有这个相当荒谬的函数:

let evaluate hand =
    if isRoyalFlush hand then 9
    elif isStraightFlush hand then 8
    elif isFour hand then 7
    elif isFullHouse hand then 6
    elif isFlush hand then 5
    elif isStraight hand then 4
    elif isThree hand then 3
    elif isTwoPair hand then 2
    elif isPair hand then 1
    else 0

所有isSomething关键字都是接受string array并返回布尔值的函数。有没有更优雅的方式使用模式匹配?

这行不通:

match true with
| isRoyalFlush hand -> 9
| isStraightFlush hand -> 8
// .. etc

我在找这样的东西:

match hand with 
| isRoyalFlush -> 9
| isStraightFlush -> 8
// .. etc

我记得曾经看到过类似的东西，但我不记得在哪里或如何找到它

Answer 1

你想要活动模式:

let (|IsRoyalFlush|_|) hand =
    if isRoyalFlush hand then Some () else None
let (|IsStraightFlush|_|) hand =
    if isStraightFlush hand then Some() else None
// etc.
match hand with
| IsRoyalFlush -> 9
| IsStraightFlush -> 8
// etc.

或者更好的做法是，将所有的公共代码放到一个简单的活动模式构建器中:

let toActivePattern pred x =
    if pred x then Some () else None
let (|IsRoyalFlush|_|) = isRoyalFlush |> toActivePattern
let (|IsStraightFlush|_|) = isStraightFlush |> toActivePattern
// etc.
match hand with
| IsRoyalFlush -> 9
| IsStraightFlush -> 8
// etc.

如果你不明白第二个例子是如何工作的，请留下评论，我将更深入地讨论。

组合活动模式

由于活动模式只是函数，因此可以使用标准的函数组合将它们连接在一起。几乎是标准的函数组合。>>算子的正常函数组合意味着"取函数1的结果，作为函数2的输入"。但是这里，函数1和函数2都返回Some ()，但是取整型;你不能把1的输出传递给2的输入，因为它们不是兼容的类型。但实际上我们想要的是将相同的输入传递给两个函数，并组合它们的输出。

因此，我们不使用普通的函数组合，而是定义我们自己的函数，它接受两个活动模式，如果两个模式都与输入匹配，则返回Some ():

let matchesBoth pattern1 pattern2 x =
  match pattern1 x with
  | None -> None
  | Some _ -> pattern2 x

在这里，让我们定义一个自定义运算符，这样你就可以看到它是如何工作的。这个matchesBoth函数的工作方式与&&操作符非常相似，因为只有当两个模式对于任何给定的输入x都返回Some ()时，它才会返回Some ()。我们不应该重载&&操作符以获取不同的类型，所以让我们创建一个看起来像&&的自定义操作符，但提醒我们它结合了两个活动模式。如果我们的运算符看起来像|&&|，那应该是完美的。我们来创建它:

let (|&&|) = matchesBoth

就是这样!现在我们可以这样做:

let (|Div3|_|) n =
  if n % 3 = 0 then Some () else None
let (|Div5|_|) n =
  if n % 5 = 0 then Some () else None
let (|Div15|_|) = (|Div3|_|) |&&| (|Div5|_|)
let fizzbuzz n =
    match n with
    | Div15 -> "FizzBuzz"
    | Div5 -> "Buzz"
    | Div3 -> "Fizz"
    | _ -> string n
fizzbuzz 30  // Result: "FizzBuzz"
fizzbuzz 31  // Result: "31"

或者，例如:

let (|IsStraightFlush|_|) = (|IsStraight|_|) |&&| (|IsFlush|_|)

Answer 2

活动模式当然是另一种选择，但我有时使用函数和值表:

let handScores = 
  [|
  //Which hand?       Score
    isRoyalFlush    , 9
    isStraightFlush , 8
    isFour          , 7
    isFullHouse     , 6
    isFlush         , 5
    isStraight      , 4
    isThree         , 3
    isTwoPair       , 2
    isPair          , 1
    (fun _ -> true) , 0 // Matches all hands
  |]
let handScore hand = 
  handScores 
  |> Array.pick (fun (t, s) -> if t hand then Some s else None)