如何在 FParsec 中解析同类列表

Question

我在尝试解析 FParsec 中类似 json 的同类数组时遇到问题。我已经将问题分解为一个重现它的简短示例。

#r @"..packagesFParsec.1.0.2libnet40-clientFParsecCS.dll"
#r @"..packagesFParsec.1.0.2libnet40-clientFParsec.dll"
open System
open FParsec
let test p str =
        match run p str with
        | Success(result, _, _)   -> printfn "Success: %A" result
        | Failure(errormsg, _, _) -> printfn "Failure: %s" errormsg

type CValue = CInt of int64
            | CBool of bool
            | CList of CValue list
let P_WHITESPACE = spaces
let P_COMMA = pstring ","
let P_L_SBRACE = pstring "[" .>> P_WHITESPACE
let P_R_SBRACE = P_WHITESPACE >>. pstring "]"
let P_INT_VALUE = pint64 |>> CInt
let P_TRUE = stringReturn "true" (CBool true)
let P_FALSE = stringReturn "false" (CBool false)
let P_BOOL_VALUE = P_TRUE <|> P_FALSE

let P_LIST_VALUE =
    let commaDelimitedList ptype = sepBy (ptype .>> P_WHITESPACE) (P_COMMA .>> P_WHITESPACE)
    let delimitedList = (commaDelimitedList P_INT_VALUE) <|> (commaDelimitedList P_BOOL_VALUE)
    let enclosedList = between P_L_SBRACE P_R_SBRACE delimitedList
    enclosedList |>> CList

当我使用 test 函数进行尝试时，我得到以下结果：

test P_LIST_VALUE "[1,2,3]"
Success: CList [CInt 1L; CInt 2L; CInt 3L]
test P_LIST_VALUE "[true,false]"
Failure: Error in Ln: 1 Col: 2
[true,false]
 ^
Expecting: integer number (64-bit, signed) or ']'

如果我在使用 <|> 运算符时交换P_INT_VALUE和P_BOOL_VALUE的顺序，那么[true,false]解析成功，但[1,2,3]失败并出现类似的错误。所以基本上，我首先使用的解析器就是它尝试使用的东西。

我知道如果 LHS 改变用户状态，<|>运算符不会尝试 RHS 解析器 - 但我看不出这是怎么回事。P_BOOL_VALUE 和 P_INT_VALUE 没有任何共同的起始字符，因此在尝试分析错误的数据类型时，两者都应该立即失败。整数从不以"假"或"真"开头，布尔值从不以数字开头。

我做错了什么？

Answer 1

啊，我想通了。错误消息中的提示是 or ']' 。问题是sepBy在空输入上成功，所以当它命中t时，它成功返回一个空列表，然后控制传递回between，尝试但未能找到终止]。

解决方案是将空列表大小写移出特定于 int/bool 的解析器，如下所示：

let P_LIST_VALUE =
    let commaDelimitedList ptype = sepBy1 (ptype .>> P_WHITESPACE) (P_COMMA .>> P_WHITESPACE)
    let delimitedList = (commaDelimitedList P_INT_VALUE) <|> (commaDelimitedList P_BOOL_VALUE) <|> preturn []
    let enclosedList = between P_L_SBRACE P_R_SBRACE delimitedList
    enclosedList |>> CList

请注意使用 sepBy1 代替 sepBy ，并且添加 <|> preturn [] 仅在delimitedList中处理一次空情况。

作为旁注，我不知道您的确切应用程序，但是在解析器中强制键入通常不是一个好主意;实现这一点的更常见方法是仅解析commaDelimitedList (P_INT_VALUE <|> P_BOOL_VALUE)(使用原始commaDelimitedList(，然后在后续分析阶段检查键入。