从基于 URI 前缀的 DBpedia SPARQL 查询中排除结果

Question

如何在使用 DBpedia SPARQL 端点时排除一组概念？我使用以下基本查询来获取概念列表：

SELECT DISTINCT ?concept
WHERE {
    ?x a ?concept
}
LIMIT 100

SPARQL结果

这给了我一个包含 100 个概念的列表。我想排除属于 YAGO 类/组的所有概念(即，其 IRI 以 http://dbpedia.org/class/yago/ 开头(。我可以像这样过滤掉单个概念：

SELECT DISTINCT ?concept
WHERE {
    ?x a ?concept
    FILTER (?concept != <http://dbpedia.org/class/yago/1950sScienceFictionFilms>)
}
LIMIT 100

SPARQL结果

但我似乎无法理解的是，如何从我的结果中排除所有 YAGO 子类？我尝试使用这样的*，但这没有实现任何效果：

FILTER (?concept != <http://dbpedia.org/class/yago/*>)

更新：

这个带有regex的查询似乎可以解决问题，但它真的非常非常慢和丑陋。我真的很期待更好的选择。

SELECT DISTINCT ?type WHERE {
  [] a ?type
  FILTER( regex(str(?type), "^(?!http://dbpedia.org/class/yago/).+"))
}
ORDER BY ASC(?type)
LIMIT 10

Answer 1

这可能看起来有点尴尬，但你关于强制转换为字符串并进行一些基于字符串的检查的评论可能是正确的。您可以使用SPARQL 1.1函数更有效地完成此操作strstarts：

SELECT DISTINCT ?concept
WHERE {
    ?x a ?concept
    FILTER ( !strstarts(str(?concept), "http://dbpedia.org/class/yago/") )
}
LIMIT 100

SPARQL结果

另一种选择是找到一个顶级YAGO类，并排除rdfs:subClassOf该顶级类的概念。 从长远来看，这可能是一个更好的解决方案(因为它不需要转换为字符串，并且它基于图结构(。 不幸的是，看起来没有一个顶级的YAGO类可以与owl:Thing相媲美。 我刚刚从 DBpedia 的下载页面下载了 YAGO 类型层次结构，并针对它运行了此查询，该查询要求没有超类的类：

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
select distinct ?root where {
  [] rdfs:subClassOf ?root 
  filter not exists { ?root rdfs:subClassOf ?superRoot }
}

我得到了这九个结果：

----------------------------------------------------------------
| root                                                         |
================================================================
| <http://dbpedia.org/class/yago/YagoLegalActorGeo>            |
| <http://dbpedia.org/class/yago/WaterNymph109550125>          |
| <http://dbpedia.org/class/yago/PhysicalEntity100001930>      |
| <http://dbpedia.org/class/yago/Abstraction100002137>         |
| <http://dbpedia.org/class/yago/YagoIdentifier>               |
| <http://dbpedia.org/class/yago/YagoLiteral>                  |
| <http://dbpedia.org/class/yago/YagoPermanentlyLocatedEntity> |
| <http://dbpedia.org/class/yago/Thing104424418>               |
| <http://dbpedia.org/class/yago/Dryad109551040>               |
----------------------------------------------------------------

鉴于 YAGO 概念不像其他一些概念那样结构化，在这种情况下，基于字符串的方法似乎是最好的。 但是，如果您愿意，可以执行这样的非基于字符串的查询，该查询要求 100 个概念，不包括那些将这九个结果之一作为超类的概念：

select distinct ?concept where {
  [] a ?concept .
  filter not exists {
    ?concept rdfs:subClassOf* ?super .
    values ?super { 
      yago:YagoLegalActorGeo
      yago:WaterNymph109550125
      yago:PhysicalEntity100001930
      yago:Abstraction100002137
      yago:YagoIdentifier
      yago:YagoLiteral
      yago:YagoPermanentlyLocatedEntity
      yago:Thing104424418
      yago:Dryad109551040
    }
  }
}
limit 100

SPARQL结果

我不确定哪个最终更快。 第一个需要转换为字符串，而strstarts如果以幼稚的方式实现，则必须在每个概念中消耗http://dbpedia.org/class/，然后才能出现问题。 第二个需要九个比较，如果IRI被扣留，则只是对象身份检查。 这是一个值得进一步研究的有趣问题。