按xml字母顺序对数据进行排序

Question

输入XML:

<?xml version="1.0" encoding="utf-8" ?>
<infoset>
  <info>
    <title>Bill</title>
    <group>
      <code>state</code>
    </group>
  </info>
  <info>
    <title>Auto</title>
    <group>
      <code>state</code>
    </group>
  </info>
  <info>
    <title>Auto2</title>
  </info>
  <info>
    <title>Auto3</title>
  </info>
  <info>
    <title>Auto5</title>
  </info>
  <info>
    <title>Certificate</title>
    <group>
      <code>Auto4</code>
    </group>
  </info>
  </infoset>

预期输出：

A
Auto2
Auto3
Auto4
   Certificate
Auto5
S
state
   Auto
   Bill

我需要按字母顺序排列标题和代码。如果信息具有组，则磁贴应位于组之下。我使用的是visualstudio2010，xslt1.0处理器和xml编辑器。

Answer 1

XSLT中的排序是直接的。你真正需要知道的是如何对项目进行"分组"。正如MichaelKay所评论的那样，XSLT2.0比XSLT1.0更容易做到这一点。在XSLT1.0中，您倾向于使用Muenchian Grouping方法，当您第一次看到它时，它看起来很混乱，但通常是最有效的方法

从输出的外观来看，您正在进行两次分组。首先，按第一个字母，然后按组/代码（如果存在）或标题。

Muenchian Grouping通过定义一个键来实现快速查找"group"中的所有项。对于组/代码或标题的第一个字母，您可以这样定义

<xsl:key name="letter" match="info" use="substring(concat(group/code, title), 1, 1)"/>

（注意：这是区分大小写的，因此如果可以混合使用小写和大写的起始字母，则可能需要使用"translate"函数）。

如果存在组/code，它将使用该组的第一个字母，否则它将拾取标题的第一个字符。

对于组/代码或标题本身，密钥如下

<xsl:key name="info" match="info" use="title[not(../group)]|group/code"/>

因此，它只在不存在"group"元素的情况下使用"title"元素。

要获得第一个分组的不同首字母，请选择所有info元素，并检查它们是否是给定字母的关键字中的第一个元素。就是这样做的

<xsl:apply-templates 
     select="info
             [generate-id() 
              = generate-id(key('letter', substring(concat(group/code, title), 1, 1))[1])]" 
     mode="letter">
  <xsl:sort select="substring(concat(group/code, title), 1, 1)" />
</xsl:apply-templates>

此处使用"模式"是因为最终XSLT必须使用与info匹配的模板。

在匹配模板中，要按代码/组或标题进行分组，则可以执行此

<xsl:apply-templates 
     select="key('letter', $letter)
            [generate-id() = generate-id(key('info', title[not(../group)]|group/code)[1])]">
  <xsl:sort select="title[not(../group)]|group/code" />
</xsl:apply-templates>

最后，要输出最后一组中的所有元素，只需再次使用密钥

<xsl:apply-templates select="key('info', $value)[group/code=$value]/title">

这是完整的XSLT。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" indent="yes"/>
  <xsl:key name="letter" match="info" use="substring(concat(group/code, title), 1, 1)"/>
  <xsl:key name="info" match="info" use="title[not(../group)]|group/code"/>
  <xsl:template match="/*">
    <xsl:apply-templates select="info[generate-id() = generate-id(key('letter', substring(concat(group/code, title), 1, 1))[1])]" mode="letter">
      <xsl:sort select="substring(concat(group/code, title), 1, 1)" />
    </xsl:apply-templates>
  </xsl:template>
  <xsl:template match="info" mode="letter">
    <xsl:variable name="letter" select="substring(concat(group/code, title), 1, 1)" />
    <xsl:value-of select="concat($letter, '&#10;')" />
    <xsl:apply-templates select="key('letter', $letter)[generate-id() = generate-id(key('info', title[not(../group)]|group/code)[1])]">
      <xsl:sort select="title[not(../group)]|group/code" />
    </xsl:apply-templates>
  </xsl:template>
  <xsl:template match="info">
    <xsl:variable name="value" select="title[not(../group)]|group/code" />
    <xsl:value-of select="concat($value, '&#10;')" />
    <xsl:apply-templates select="key('info', $value)[group/code=$value]/title">
      <xsl:sort select="." />
    </xsl:apply-templates>
  </xsl:template>
  <xsl:template match="title">
    <xsl:value-of select="concat('   ', ., '&#10;')" />
  </xsl:template>
</xsl:stylesheet>

当应用于XML时，以下是输出

A
Auto2
Auto3
Auto4
   Certificate
Auto5
s
state
   Auto
   Bill