XSLT换行除一个元素外的任意元素

Question

我一直在关注这个主题，但仍然无法解决下面描述的问题。在<ol>元素内部，我需要根据以下示例将任意元素（/节点）封装到<li>中：

<ol>
    text
    <p>text</p>
    <li>
        text
        <p>text</p>
    </li>
    <p>text</p>
    text
    <sub>text</sub>
</ol>

转换为：

<ol>
    <li>
        text
        <p>text</p>
    </li>
    <li>
        text
        <p>text</p>
    </li>
    <li>
        <p>text</p>
        text
        <sub>text</sub>
    </li>
</ol>

我正在使用xslt 1.0。非常感谢您的帮助！

更新的示例

<root>
    <ol>
        text
        <p>text</p>
        <li>
           text
           <p>text</p>
        </li>
        <p>text</p>
        text
        <sub>text</sub>
    </ol>
    <ol>
        text
        <p>text</p>
    </ol>
</root>

转换为：

<root>
    <ol>
        <li>
            text
            <p>text</p>
        </li>
        <li>
            text
            <p>text</p>
        </li>
        <li>
            <p>text</p>
            text
            <sub>text</sub>
        </li>
    </ol>
    <ol>
        <li>
            text
            <p>text</p>
        </li>
    </ol>
</root>

Answer 1

我会尝试将其解决为Muenchian分组，其中密钥计算ol元素的所有非li子节点的preceding-sibling::li元素：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:key name="group" match="ol/node()[not(self::li)]" use="count(preceding-sibling::li)"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="ol/node()[not(self::li)][generate-id() = generate-id(key('group', count(preceding-sibling::li))[1])]">
        <li>
            <xsl:copy-of select="key('group', count(preceding-sibling::li))"/>
        </li>
    </xsl:template>
    <xsl:template match="ol/node()[not(self::li)][not(generate-id() = generate-id(key('group', count(preceding-sibling::li))[1]))]"/>
</xsl:transform>

在线样本位于http://xsltransform.net/pPzifpy.