正在提取边缘列表中的特定行

Question

我有一个大型网络文件，其中有数百万条无向边：edge.txt具有节点1、结点2和一些数值属性

a   b   0.8
b   c   0.1
d   f   0.7
e   f   0.5
c   b   0.1
b   a   0.8
a   c   0.1

给定另一个文件input.txt

a
b
c

只有在input.txt中同时具有节点(node1和node2(的边才能打印

a   b   0.8
b   c   0.1
a   c   0.1

我试过了：

awk 'FNR==NR {a[$0]++;next}{if ($1 in a && $2 in a) {print}}' input.txt edge.txt

需要一些建议吗？感谢

Answer 1

您可以尝试这个awk脚本：

awk 'NR==FNR{a[$1];next}($1 in a)&&($2 in a)' input.txt edge.txt

数组查找需要括在括号内，并且不需要print语句(因为这是条件有效时的默认语句(。

Answer 2

@oliv的方法是正确的方法，但如果你想删除转置对，你需要添加更多的条件

$ awk 'NR==FNR{a[$1]=1; next} a[$1] && a[$2] && !b[$1,$2]++ && !b[$2,$1]++' input edge
a   b   0.8
b   c   0.1
a   c   0.1

Answer 3

另一个尝试最小化对哈希b的查找的方法，如果edge>>输入：

$ awk '
NR==FNR && !($1 in a) {   # if node not in hash a yet, ie. remove duplicates in input
for(i in a) {         # "c" -> a[]: insert to b: ca, ac, cb, bc
b[$1 i]
b[i $1]
}
a[$1]                 # new entries go to a as well
next
}
($1 $2 in b) {
# delete b[$1 $2]     # uncomment these to remove duplicates
# delete b[$2 $1]     # ie. "a b 0.8" vs. "b a 0.8"
print
}' input edge  # if both $1 and $2 are in a, $1 $2 is in b

输出：

a   b   0.8
b   c   0.1
c   b   0.1
b   a   0.8
a   c   0.1

删除重复项后：

a   b   0.8
b   c   0.1
a   c   0.1