编写一个简单的引导加载程序来读取用户名

Question

我正在尝试学习操作系统的工作原理。这是我很难解决的一项简单任务：编写一个简单的引导加载程序，提示用户输入他的名字并打印一条欢迎消息，例如"你好，>>姓名<<" - 之后，它什么都不做。

我正在运行minix 3qemu，如果这有任何相关性。我只是编译一个asm文件并将其前 512 个字节dd到/dev/c0d0(minix的虚拟硬盘驱动器)。

我可以打印消息并打印用户正在键入的内容。但是，之后我没有设法打印用户名。

这是我的汇编代码：

[bits 16]
[org 0x7c00]
mov si, HelloString
call print_string
mov di, name
call read_name
mov si, name
call print_string
read_name:
read_char:
mov ah, 0h  ; read character from keyboard
mov [di], ah    ; save it in the buffer
inc di      ; next char
int 0x16    ; store it in AL
cmp ah, 0x0d    ; check for enter
je stop_reading 
mov ah, 0eh     ; display character in AL
int 0x10    ; echo it
jmp read_char   ; an so on
stop_reading:
mov si, EoL
call print_string
ret
print_char:
mov ah, 0x0e    ; one char
mov bh, 0x00    ; page number
mov bl, 0x07    ; font color
int 0x10
ret
print_string:
next_char:
mov al, [si]
inc si
or al, al
jz exit_function
call print_char
jmp next_char
exit_function:
ret
;data
HelloString db 'Enter your name', 0xd, 0xa, 0
name times 20 db 0
EoL db 0xd, 0xa, 0
times 510 - ($ - $$) db 0;
dw 0xaa55

我做错了什么？

Answer 1

您的代码存在许多问题。罗斯和我在评论中指出了一些。您应该阅读我的一般引导加载程序提示。虽然与您的实际问题无关，但您应该将DS(如果您最终需要它，则为ES)设置为 0，因为您使用的起点为 0x7c00 (org 0x7c00)。您还应该在知道代码不会破坏的地方设置堆栈。我会在之前将此代码添加到顶部：

mov si, HelloString
call print_string

将其更改为：

xor ax, ax         ; AX=0
mov ds, ax
mov es, ax
mov ss, ax         ; SS=ES=DS=0
mov sp, 0x7c00     ; Place stack before the bootloader. Grows down from 0x0000:0x7c00
mov si, HelloString
call print_string

代码运行完毕后，您应该将 CPU 置于无限循环中，这样它就不会通过执行主代码下的函数来继续。所以在标签之前read_name:放置一个无限循环。像这样的事情很典型：

cli                ; Turn off interrupts        
endloop:
hlt                ; Halt processor until next interrupt encountered
jmp endloop        ; Jump back just in case we get an MNI (non-maskable interrupt)

您的read_char函数中有一些错误。BIOS 中断信息的最佳位置之一是 Ralph Brown 的中断列表。Int 0x16/AH=0 记录为：

AH = 00h
Return:
AH = BIOS scan code
AL = ASCII character

您应该使用AL中的 ASCII 字符来存储到字符串缓冲区中。您还应该将AL 与 0x0d进行比较，而不是AH(这是键盘扫描代码，而不是 ASCII 字符)。在读取带有int 0x16的字符之前，您还将数据存储到字符串缓冲区中。之后您需要将它们放入缓冲区中。当您达到stop_reading:时，您需要在缓冲区的末尾放置一个 NUL (0x00) 字符。

read_name代码可能如下所示：

read_name:
read_char:
mov ah, 0h  ; read character from keyboard
int 0x16    ; store it in AL
cmp al, 0x0d    ; check for enter
je stop_reading
mov [di], al    ; save it in the buffer
inc di      ; next char
mov ah, 0eh     ; display character in AL
int 0x10    ; echo it
jmp read_char   ; an so on
stop_reading:
mov byte [di], 0x00    ; NUL terminate buffer
mov si, EoL
call print_string
ret

修改后的引导加载程序可能如下所示：

[bits 16]
[org 0x7c00]
xor ax, ax         ; AX=0
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0x7c00     ; Place stack before the bootloader. Grows down from 0x0000:0x7c00
mov si, HelloString
call print_string
mov di, name
call read_name
mov si, name
call print_string
cli                ; Turn off interrupts        
endloop:
hlt                ; Halt processor until next interrupt encountered
jmp endloop        ; Jump back just in case we get an MNI (non-maskable interrupt)
read_name:
read_char:
mov ah, 0h         ; read character from keyboard
int 0x16           ; store it in AL
cmp al, 0x0d       ; check for enter
je stop_reading
mov [di], al       ; save it in the buffer
inc di             ; next char
mov ah, 0eh        ; display character in AL
int 0x10           ; echo it
jmp read_char      ; an so on
stop_reading:
mov byte [di], 0   ; NUL terminate buffer
mov si, EoL
call print_string
ret
print_char:
mov ah, 0x0e       ; one char
mov bh, 0x00       ; page number
mov bl, 0x07       ; font color
int 0x10
ret
print_string:
next_char:
mov al, [si]
inc si
or al, al
jz exit_function
call print_char
jmp next_char
exit_function:
ret
;data
HelloString db 'Enter your name', 0xd, 0xa, 0
name times 20 db 0
EoL db 0xd, 0xa, 0
times 510 - ($ - $$) db 0;
dw 0xaa55

---

我强烈建议使用BOCHS来调试引导加载程序。它有一个内置的调试器，可以理解实模式和实模式寻址，比QEMU更适合调试引导加载程序