XSLT1.0计数以下同级

Question

我有一个类似的简单xml

  <root>
          <story>
            <strongp>
                <color>Attention</color>
                Text of the single strongp color.
            </strongp>
            <p>Text</p>
            <strongp>
                <color>Attention</color>
                Text of strongp color.
            </strongp>
            <strongp>
                Text of interest1
                <a id="1234-3457">here</a>.
            </strongp>
            <p>sometext</p>
            <p>sometext</p>
            <el>sometext</el>
            <h5>Header H5</h5>
            <strongp>
                <color>Attention</color>
                Text of strongp color.
            </strongp>
            <strongp>
                Text of interest 
                <a id="8909-3490">here</a>
            </strongp>
            <strongp>
                Text of interest 
                <a id="8909-0081">here</a>
            </strongp>
            <strongp>
                Text of interest 
                <a id="8967-001">here</a>
            </strongp>
            <p>Text</p>
            <inline />
         </story>
  </root>

需要将strongp[color]转换为remarkheader，并将以下同级转换为remarktext，并将其全部封装到<remark>。

具有颜色的单个<strongp>所需的输出：

<remark>
    <remarkheader>Attention</remarkheader>
    <remarktext>Text of the single  strongp color.</remarktext>
</remark>

strongp with color和1个同级strongp的输出为：

<remark>
    <remarkheader>Attention</remarkheader>
    <remarktext>Text of strongp color.<br/>Text of interest1
                <a id="1234-3457">here</a>.</remarktext>
</remark>

最后输出strongp color，然后输出1个以上的strongp

<remark>
    <remarkheader>Attention</remarkheader>
    <remarktext>
        Text of strongp color.
        <br/>
        Text of interest1
        <a id="1234-3457">here</a>.
    <br/>
        Text of interest
        <a id="8909-3490">here</a>.
    <br/>
        Text of interest
        <a id="8909-0081">here</a>.
    <br/>
        Text of interest
        <a id="8967-001">here</a>.
    </remarktext>
</remark>

嗯，应用了这个模板

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  version="1.0">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
    <xsl:template match="node()|@*" name="identity" >
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="strongp[color]">
        <remark>
            <remarkheader>
                <xsl:value-of select="./color"/>
            </remarkheader>
            <remarktext>
                <xsl:value-of select="substring-after(., color)"/>
                <br/>
                <xsl:for-each select="following-sibling::strongp[count(preceding-sibling::strongp[color][1] | current())=1]">
                    <xsl:apply-templates select="./node()"  />
                    <xsl:choose>
                        <xsl:when test="position() !=last()">
                            <br/>
                        </xsl:when>
                    </xsl:choose>
                </xsl:for-each>
            </remarktext>
        </remark>
    </xsl:template>
</xsl:stylesheet>

但它似乎不太好用。它添加了来自后面第一个同级strongp[color]的文本。我真的不明白下面的兄弟姐妹怎么算。

你可以在这里看http://www.utilities-online.info/xsltransformation/?save=c1b3e857-b6d7-4562-a440-9d3e357cb12d-xsltransformation

Answer 1

这是我的尝试，递归处理following-sibling::strongp：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  version="1.0">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
<xsl:strip-space elements="*"/>
<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="strongp[color]">
    <remark>
        <remarkheader>
            <xsl:value-of select="color"/>
        </remarkheader>
        <remarktext>
            <xsl:apply-templates select="text()"/>
            <xsl:apply-templates select="following-sibling::*[1][self::strongp]" mode="following"/>
        </remarktext>
    </remark>
</xsl:template>
<xsl:template match="strongp" mode="following">
    <br/>
    <xsl:apply-templates select="node()"/>
    <xsl:apply-templates select="following-sibling::*[1][self::strongp]" mode="following"/>
</xsl:template>
<xsl:template match="strongp"/>
</xsl:stylesheet>