xQuery 删除未选定的元素

Question

我有一个名为 employees.xml 的 XML 文档：

<employees>
    <row>
        <emp_no>10001</emp_no>
        <first_name>Georgi</first_name>
        <last_name>Facello</last_name>
    </row>
    <row>
        <emp_no>10002</emp_no>
        <first_name>Bezalel</first_name>
        <last_name>Simmel</last_name>
    </row>
</employees>

我想编写一个名为 my-remove-elements 的函数，该函数将删除未选择的属性。例如，仅在 XML 文档中保留first_name和last_name：

  <employees>
        <row>
            <first_name>Georgi</first_name>
            <last_name>Facello</last_name>
        </row>
        <row>
            <first_name>Bezalel</first_name>
            <last_name>Simmel</last_name>
        </row>
    </employees>

我的函数的定义是：

declare function local:my-remove-elements($input as element(), $remove-names as xs:string*) as element() {
   element {node-name($input) }
      {$input/@*,
       for $child in $input/node()[name(.)=$remove-names]
          return
             if ($child instance of element())
                then local:my-remove-elements($child, $remove-names)
                else $child
      }
};

这是我这样称呼它的方式：

  let $doc := doc("employees.xml")
    return 
         local:my-remove-elements($doc, ('first_name', 'last_name'))

它让我"错误：XPTY0004...不是元素((的子类型..."我已经更改了代码：

let $rows:= doc("employees.xml")//row
        return 
             local:my-remove-elements($rows, ('first_name', 'last_name'))

这次仍然是："err：XPTY0004：参数 1 的实际基数与函数签名中的基数不匹配......"。您知道如何解决此问题并使其工作吗？

Answer 1

这是一个可能的解决方案：

declare function local:remove-elements(
  $node as node(),
  $keep-names as xs:string*
) as node()? {
  if($node instance of element()) then (
    let $name := name($node)
    where $name = $keep-names
    return element { $name } {
      $node/@*,
      for $child in $node/node()
      return local:remove-elements($child, $keep-names)
    }
  ) else (
    $node
  )
};
local:remove-elements(
  doc("employees.xml")/employees,
  ('employees', 'row', 'first_name', 'last_name')
)

这是另一个使用XQuery Update

的：

declare function local:remove-elements(
  $node as node(),
  $keep-names as xs:string*
) as node()? {
  copy $c := $node
  modify delete node $c//*[not(name() = $keep-names)]
  return $c
};
local:remove-elements(
  doc("employees.xml")/employees,
  ('employees', 'row', 'first_name', 'last_name')
)

Answer 2

>错误err:XPTY0004是因为您正在调用将document-node()作为第一个参数传递的函数，但第一个参数必须是element()。

更改调用它的方式，传入文档元素(即 $doc/* ( 而不是document-node()

然后，您需要调整函数中的逻辑。如果只选择与$remove-names相等的节点$child(这很令人困惑，请考虑重命名为类似 $keep-leaf-names 的名称(，则将排除employees元素。将该过滤器向下移动，并添加逻辑进行处理，如果元素具有子元素或name()等于任何$remove-names。

declare function local:my-remove-elements($input as element(), $remove-names as xs:string*) as element() {
   element {node-name($input) }
      {$input/@*,
       for $child in $input/node()
          return
             if ($child instance of element()) then 
                if ($child/* or name($child)=$remove-names) then 
                  local:my-remove-elements($child, $remove-names) 
                else ()
             else $child
      }
};