我是XSLT和XML的新手。我一直在学习教程和stackoverflow示例，并学习了很多新东西。
目前，我正在尝试将XSLT应用于XML文件，以将其转换为CSV。我试图实现的是，我在XML文件中有一些信息，我想提取这些信息。默认情况下，CSV文件将包含一些信息，我将在XSLT中传递这些信息。
我还使用了我很快学会的基本XSLT语法，我相信这是最糟糕的方法。如果有人能指导我如何使这个解决方案变得更好，我将感谢所有的帮助
我遇到的问题如下：
-
信息格式不正确，打印在新行上，除非我为新行指定，否则我不希望这样。此外，如果我不缩进XSLT文件，那么信息就可以保持为单一类，但代码看起来一团糟，我相信有一些简单的方法可以做到这一点。
-
每个人都会有一些许可证，我想在每个循环中阅读这些许可证，但我不知道如何做到这一点。如果这个人没有一些许可证，那么默认情况下我希望它是空白的。目前在这个例子中，我使用了5个状态。
这是我用来测试的xml文件。
<?xml version="1.0" encoding="UTF-8"?>
<People>
<Person>
<required-tag1>some-information</required-tag1>
<required-tag2>some-information</required-tag2>
<first-name>Mike</first-name>
<last-name>Hewitt</last-name>
<licenses>
<license>
<state xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">IL</state>
</license>
</licenses>
</Person>
<Person>
<required-tag1>some-information</required-tag1>
<required-tag2>some-information</required-tag2>
<first-name>John</first-name>
<last-name>Jhonny</last-name>
<licenses>
<license>
<state xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">NY</state>
</license>
</licenses>
</Person>
<Person>
<required-tag1>some-information</required-tag1>
<required-tag2>some-information</required-tag2>
<first-name>Xmen</first-name>
<last-name>Bat</last-name>
<licenses>
<license>
<state xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">AK</state>
</license>
<license>
<state xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">CA</state>
</license>
<license>
<state xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">IL</state>
</license>
<license>
<state xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">NY</state>
</license>
<license>
<state xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">TX</state>
</license>
</licenses>
</Person>
</People>
我编写的XSLT如下：
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:csv="csv:csv" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output encoding="UTF-8" method="text"/>
<xsl:template match="/People">First Name,Last Name,AK,CA,IL,NY,TX,default value1,required-tag1,required-tag2,default value2,default value3
<xsl:for-each select="Person">
<xsl:value-of select="first-name"/>, <xsl:value-of select="last-name"/>,<xsl:choose>
<xsl:when test="licenses/license/state='AK'">
<xsl:value-of select="licenses/license/state"/>,
</xsl:when>
<xsl:otherwise>NA,
</xsl:otherwise></xsl:choose><xsl:choose>
<xsl:when test="licenses/license/state='CA'">
<xsl:value-of select="licenses/license/state"/>,
</xsl:when>
<xsl:otherwise>NA,
</xsl:otherwise></xsl:choose><xsl:choose>
<xsl:when test="licenses/license/state='IL'">
<xsl:value-of select="licenses/license/state"/>,
</xsl:when>
<xsl:otherwise>NA,
</xsl:otherwise></xsl:choose><xsl:choose>
<xsl:when test="licenses/license/state='NY'">
<xsl:value-of select="licenses/license/state"/>,
</xsl:when>
<xsl:otherwise>NA,
</xsl:otherwise></xsl:choose><xsl:choose>
<xsl:when test="licenses/license/state='TX'">
<xsl:value-of select="licenses/license/state"/>,
</xsl:when>
<xsl:otherwise>NA,
</xsl:otherwise></xsl:choose>DEFAULT VALUE1,<xsl:value-of select="required-tag1"/>,<xsl:value-of select="required-tag2"/>,DEFAULT VALUE2,DEFAULT VALUE3<xsl:text>
</xsl:text>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
对于许可证，我尝试在for each循环中使用for each环路，但对于所有许可证，该循环执行了5次，我如何执行条件以测试许可证状态5次，并保持默认格式正确。
这就是我想要输出的方式：
First Name,Last Name,AK,CA,IL,NY,TX,default value1,required-tag1,required-tag2,default value2,default value3
Mike, Hewitt,NA,NA,IL,NA,NA,DEFAULT VALUE1,some-information,some-information,DEFAULT VALUE2,DEFAULT VALUE3
John, Jhonny,NA,NA,NA,NY,NA,DEFAULT VALUE1,some-information,some-information,DEFAULT VALUE2,DEFAULT VALUE3
Xmen, Bat,AK,CA,IL,NY,TX,DEFAULT VALUE1,some-information,some-information,DEFAULT VALUE2,DEFAULT VALUE3
我使用的是XSLT 1.0版本。
谢谢你的帮助。
对于新行的问题，请考虑当前如何编写NA作为示例
<xsl:otherwise>NA,
</xsl:otherwise>
现在，如果你只有这个。。。
<xsl:otherwise>
</xsl:otherwise>
那么XSLT根本不会输出新行。xsl:otherwise下有一个文本节点，但它是一个仅限空白的节点，因此它被忽略。但是，一旦向其中添加普通文本（如NA），XSLT就会认为所有文本都很重要，并输出包括新行在内的文本。它不会规范化任何空间。
解决方案是将所有此类文本包装在xsl:text 中
<xsl:otherwise>
<xsl:text>NA</xsl:text>
</xsl:otherwise>
至于你的逻辑问题，你目前这样做是为了检查状态
<xsl:when test="licenses/license/state='IL'">
<xsl:value-of select="licenses/license/state"/>,
</xsl:when>
但licenses/license/state在每一句话中的使用都有细微的区别。在xsl:when中，您会问"是否有此州的许可证"，但在xsl:value-of中，它将获得列表中的第一个州！
现在，你可以写这个
<xsl:when test="licenses/license/state='IL'">
<xsl:value-of select="licenses/license[state='IL']/state"/>
<xsl:text>,</xsl:text>
</xsl:when>
但这是多余的。最好简化为这个
<xsl:when test="licenses/license/state='IL'">
<xsl:text>IL,</xsl:text>
</xsl:when>
同样值得一提的是，您显然有很多重复的代码，所以您可以通过使用命名模板来删除其中的一些代码。
试试这个XSLT作为的例子
<xsl:stylesheet version="1.0" xmlns:csv="csv:csv" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output encoding="UTF-8" method="text"/>
<xsl:template match="/People">
<xsl:text>First Name,Last Name,AK,CA,IL,NY,TX,default value1,required-tag1,required-tag2,default value2,default value3</xsl:text>
<xsl:text>
</xsl:text>
<xsl:for-each select="Person">
<xsl:value-of select="first-name"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="last-name"/>
<xsl:text>, </xsl:text>
<xsl:call-template name="state">
<xsl:with-param name="stateCode" select="'AK'" />
</xsl:call-template>
<xsl:call-template name="state">
<xsl:with-param name="stateCode" select="'CA'" />
</xsl:call-template>
<xsl:call-template name="state">
<xsl:with-param name="stateCode" select="'IL'" />
</xsl:call-template>
<xsl:call-template name="state">
<xsl:with-param name="stateCode" select="'NY'" />
</xsl:call-template>
<xsl:call-template name="state">
<xsl:with-param name="stateCode" select="'TX'" />
</xsl:call-template>
<xsl:text>DEFAULT VALUE1,</xsl:text>
<xsl:value-of select="required-tag1"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="required-tag2"/>
<xsl:text>,DEFAULT VALUE2,DEFAULT VALUE3</xsl:text>
<xsl:text>
</xsl:text>
</xsl:for-each>
</xsl:template>
<xsl:template name="state">
<xsl:param name="stateCode" />
<xsl:choose>
<xsl:when test="licenses/license[state=$stateCode]">
<xsl:value-of select="$stateCode"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>NA</xsl:text>
</xsl:otherwise>
</xsl:choose>
<xsl:text>,</xsl:text>
</xsl:template>
</xsl:stylesheet>
随着xsl:call-template的重复使用，这仍然是相当重复的。如果您只想要5个固定状态，那么您可以将这些状态放在一个外部XML文档中，并在上面循环，例如。不过，这将是另一个问题。。。。。