使用XSLT1.0将两个节点转换为一个节点

Question

输入：

<cp>
...
<conEmail>eeee</conEmail>
<conPhone>1800<conPhone>
...
</cp>

输出：

<cp>
...
<con>
 <email>eeee</email>
 <phone>1800</phone>
</con>
...
</cp>

Xsl-t

<xsl:template match="*[starts-with(name(), 'con')]">
<xsl:element name="con">
<xsl:element name="email">
    <xsl:value-of select="." />
</xsl:element>
<xsl:element name="phone">
    <xsl:value-of select="following-sibling::*[1]"></xsl:value-of>
</xsl:element>
</xsl:element>
</xsl:template>

我尝试与*[starts-with(name(), 'con')]匹配，但它匹配了两次节点。。。有什么帮助吗？

Answer 1

很难回答只包含片段的问题，因为整体上下文很重要。

以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:template match="/cp">
    <xsl:copy>
        <!-- other things? -->
        <con>
            <xsl:apply-templates select="*[starts-with(name(), 'con')]"/>   
        </con>
        <!-- more of other things? -->
    </xsl:copy>
</xsl:template>
<xsl:template match="*[starts-with(name(), 'con')]">
    <xsl:element name="{substring-after(local-name(),'con')}">
        <xsl:value-of select="." />
    </xsl:element>
</xsl:template>
</xsl:stylesheet>

当应用于您的输入时（在更正未关闭的conPhone标签后！），将返回：

<?xml version="1.0" encoding="utf-8"?>
<cp>
   <con>
      <Email>eeee</Email>
      <Phone>1800</Phone>
   </con>
</cp>

如果您提前知道"con*"元素的名称，那么最好显式处理它们，例如：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:template match="/cp">
    <xsl:copy>
        <!-- other things? -->
        <con>
            <xsl:apply-templates select="conEmail | conPhone"/> 
        </con>
        <!-- more of other things? -->
    </xsl:copy>
</xsl:template>
<xsl:template match="conEmail">
    <email>
        <xsl:value-of select="." />
    </email>
</xsl:template>
<xsl:template match="conPhone">
    <phone>
        <xsl:value-of select="." />
    </phone>
</xsl:template>
</xsl:stylesheet>

返回：

<?xml version="1.0" encoding="utf-8"?>
<cp>
   <con>
      <email>eeee</email>
      <phone>1800</phone>
   </con>
</cp>