如何在日志文件中打印命令行本身以进行日志跟踪

Question

我有一个通过.bat文件调用的java代码。批处理工作正常。有没有办法将我正在执行的命令行打印到标准输出(日志(文件中？

例如，我的命令是

call dpp.bat -r %BASE_URL% views -af xyz.csv >> creation.log 2>&1

在我的蝙蝠文件中，我有多个各种类型的此类命令。在执行此单个批处理文件时，所有内容将逐个执行，并且所有日志都将写入该单个文件创建.log。用户迷失了看到日志，哪个命令行执行了什么！

有没有一种简单的方法，例如添加一些行，也可以将命令行打印到日志文件中？

Answer 1

如果我理解正确，您希望将命令回显和命令输出写入日志文件。

为此，您可以执行以下操作：

• 将要记录的代码放入子例程中，然后由call调用。
• 仅将 call 命令的输出重定向到日志文件。
• 将@echo off放入批处理文件的主要部分。
• 将@echo on放入子例程中。
• 不要忘记将exit /B放在主要部分的末尾。

下面是一个示例：

@rem // Turn command echoes off in the main section:
@echo off
@rem // Redirect only the output of `call` to the log file:
call :SUB >> "creation.log" 2>&1
@rem // Terminate main section:
@exit /B
:SUB
    @rem // Turn command echoes on in the sub-section:
    @echo on
    @rem /* Place all command lines you want to log here;
    @rem    ensure NOT to precede these lines with `@`: */
    call dpp -r %BASE_URL% views -af xyz.csv
    @rem // Terminate sub-section:
    @exit /B

---

或者，您可以将每个命令放入仅迭代一次的for循环中：

@rem // Turn command echoes on:
@echo on
@rem // Place all command lines you want to log into `for` loops that iterate once:
@(for %%# in (.) do call dpp -r %BASE_URL% views -af xyz.csv) > "creation.log" 2>&1
@rem // Terminate script:
@exit /B

<</div> div class="one_answers">

其实很简单，就放echo %* 这将打印在命令行中传递的参数。