剪辑:迫使规则重新评估全局变量的价值

Question

是否有可能导致剪辑重新评估碎屑中全局变量的值？我有这个：

(defrule encourage "Do we have a GPA higher than 3.7?"
    (test (> (gpa) 3.7))
    =>
    (printout t "Keep up the excellent work!" crlf))

GPA是基于两个全局变量（成绩和信用次数）计算并返回数字的函数。我在某个地方阅读了更改全局变量的地方，不会调用模式匹配。我该如何强迫这个？只要GPA高于3.7。

Answer 1

不要以这种方式尝试使用全局变量或函数调用。首先，全局变量是专门设计用于不触发图案匹配的。其次，剪辑要知道何时需要重新评估函数调用需要一些魔术，因为有任何数量的更改可能会导致函数返回不同的值，而不仅仅是更改全球范围。如果您想要一条特定的信息来触发图案匹配，请将其粘贴在事实或实例中。如果您将函数调用并绑定为在规则条件下用作参数的值，它将使您的代码更容易理解。

CLIPS> (clear)
CLIPS> 
(deffunction gpa (?grade-points ?number-of-credits)
   (/ ?grade-points ?number-of-credits))
CLIPS>    
(defrule encourage "Do we have a GPA higher than 3.7?"
    (grade-points ?gp)
    (number-of-credits ?noc)
    (test (> (gpa ?gp ?noc) 3.7))
    =>
    (printout t "Keep up the excellent work!" crlf))
CLIPS> (assert (grade-points 35) (number-of-credits 10))
<Fact-2>
CLIPS> (agenda)
CLIPS> (facts)
f-0     (initial-fact)
f-1     (grade-points 35)
f-2     (number-of-credits 10)
For a total of 3 facts.
CLIPS> (retract 1)
CLIPS> (assert (grade-points 38))
<Fact-3>
CLIPS> (agenda)
0      encourage: f-3,f-2
For a total of 1 activation.
CLIPS>

另外，您可以使用事实查询函数在一组事实上迭代，以根据事实而不是全球群体动态计算GPA。每次修改这些事实之一（添加或删除）时，您还可以断言一个事实，表明需要重新检查GPA以触发鼓励规则。

CLIPS> (clear)
CLIPS> 
(deftemplate grade
   (slot class)
   (slot grade-points)
   (slot credits))
CLIPS> 
(deffunction gpa ()
   (bind ?grade-points 0)
   (bind ?credits 0)
   (do-for-all-facts ((?g grade)) TRUE
      (bind ?grade-points (+ ?grade-points ?g:grade-points))
      (bind ?credits (+ ?credits ?g:credits)))
   (if (= ?credits 0)
      then 0
      else (/ ?grade-points ?credits)))
CLIPS> 
(defrule encourage
   ?f <- (check-gpa)
   =>
   (retract ?f)
   (if (> (gpa) 3.7)
      then
      (printout t "Keep up the excellent work!" crlf)))
CLIPS> (gpa)
0
CLIPS> (assert (check-gpa))
<Fact-1>
CLIPS> (run)
CLIPS>  (assert (grade (class Algebra) (grade-points 12) (credits 3)))
<Fact-2>
CLIPS> (gpa)
4.0
CLIPS> (assert (check-gpa))
<Fact-3>
CLIPS> (run)
Keep up the excellent work!
CLIPS> (assert (grade (class History) (grade-points 6) (credits 2)))
<Fact-4>
CLIPS> (gpa)
3.6
CLIPS> (assert (check-gpa))
<Fact-5>
CLIPS> (run)
CLIPS> (assert (grade (class Science) (grade-points 12) (credits 3)))
<Fact-6>
CLIPS> (gpa)
3.75
CLIPS> (assert (check-gpa))
<Fact-7>
CLIPS> (run)
Keep up the excellent work!
CLIPS>