XSLT Position() 基于列值

Question

每次'column3'的值发生变化时，我都试图在行之间创建一个间隙。目前，间隙设置为每 2 行出现一次，这不是我需要的。例如，前 10 行中"column3"的值为 1，1，3，3，3，3，5，5，5，5，5我想要最后一个"1"和第一个"3"之间的差距，等等。

 <xsl:for-each select="Market">
        <tr>
          <td>
            <xsl:value-of select="Column1"/>
          </td>
          <td>
            <xsl:value-of select="Column2"/>
          </td>
          <td>
            <xsl:value-of select="Column3"/>
          </td>
        </tr>
          <xsl:if test="(position() mod 2 = 0)">
          <tr>
            <td colspan="5" height="25px" />
          </tr>
        </xsl:if>

Answer 1

您可以使用 XPath 中的以下同级轴来执行此操作。

<xsl:if test="Column3 != following-sibling::Market[1]/Column3">

即下一个市场元素是否具有具有不同值的 Column3 元素。

例如，给定以下 XML

<Markets>
    <Market>
        <Column1>A</Column1>
        <Column3>1</Column3>
    </Market>
    <Market>
        <Column1>A</Column1>
        <Column3>1</Column3>
    </Market>
    <Market>
        <Column1>A</Column1>
        <Column3>3</Column3>
    </Market>
    <Market>
        <Column1>A</Column1>
        <Column3>3</Column3>
    </Market>
    <Market>
        <Column1>A</Column1>
        <Column3>3</Column3>
    </Market>
    <Market>
        <Column1>A</Column1>
        <Column3>3</Column3>
    </Market>
    <Market>
        <Column1>B</Column1>
        <Column3>4</Column3>
    </Market>
    <Market>
        <Column1>B</Column1>
        <Column3>4</Column3>
    </Market>
</Markets>

应用以下 XSLT 时

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html" indent="yes"/>
   <xsl:template match="/Markets">
      <table>
         <xsl:apply-templates select="Market"/>
      </table>
   </xsl:template>
   <xsl:template match="Market">
      <tr>
         <td>
            <xsl:value-of select="Column1"/>
         </td>
         <td>
            <xsl:value-of select="Column3"/>
         </td>
      </tr>
      <xsl:if test="Column3 != following-sibling::Market[1]/Column3">
         <tr>
            <td colspan="2" height="25px"/>
         </tr>
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

那么下面是输出

<table>
   <tr>
      <td>A</td>
      <td>1</td>
   </tr>
   <tr>
      <td>A</td>
      <td>1</td>
   </tr>
   <tr>
      <td colspan="2" height="25px"/>
   </tr>
   <tr>
      <td>A</td>
      <td>3</td>
   </tr>
   <tr>
      <td>A</td>
      <td>3</td>
   </tr>
   <tr>
      <td>A</td>
      <td>3</td>
   </tr>
   <tr>
      <td>A</td>
      <td>3</td>
   </tr>
   <tr>
      <td colspan="2" height="25px"/>
   </tr>
   <tr>
      <td>B</td>
      <td>4</td>
   </tr>
   <tr>
      <td>B</td>
      <td>4</td>
   </tr>
</table>

（注意，为了简洁起见，我错过了 Column2）。