CLOS:使用插槽值初始化另一个插槽

Question

我对使用CLOS很陌生。在这里，我写了一种使用CLOS定义队列的可能方法：

(defclass Queue ()
    ((queue-size
        :reader queue-size
        :initarg :queue-size
        :initform (error "Provide a queue-size when initialising a Queue")
        :type number)
    (elements
        :accessor elements
        :initform (make-array queue-size :initial-element nil))
    (put-ptr
        :accessor put-ptr
        :initform 0
        :type number)
    (get-ptr
        :accessor get-ptr
        :initform 0
        :type number)))

正如您所看到的，我使用插槽queue-size的值来制作插槽elements中的数组。但是，不幸的是，这给了我以下错误：

*** - DEFAULT-ELEMENTS: variable QUEUE-SIZE has no value

正如我所说，我是CLOS的新手。有什么办法我还能做到这一点吗？是否可以覆盖某种init方法？如果是，我该怎么做？

Answer 1

在CLOS中，不能直接将插槽称为变量。此外，您不能在initforms中引用对象的其他槽。

简化示例：

CL-USER 27 > (defclass queue () (size elements))
#<STANDARD-CLASS QUEUE 4020001AB3>
CL-USER 28 > (describe (make-instance 'queue))
#<QUEUE 40200040CB> is a QUEUE
SIZE          #<unbound slot>
ELEMENTS      #<unbound slot>

现在我们将设置elements插槽：

CL-USER 36 > (defclass queue () ((size :initarg :size) elements))
#<STANDARD-CLASS QUEUE 42E0A2DBFB>

为此，我们编写了一个initialize-instance :after方法。通常的初始化发生在我们的方法运行的之后。WITH-SLOTS允许我们在代码中使用某些类似槽的变量。在这里，我们访问插槽size和elements:

CL-USER 37 > (defmethod initialize-instance :after ((q queue) &rest initargs)
               (with-slots (size elements) q
                 (setf elements (make-array size :initial-element nil))))
#<STANDARD-METHOD INITIALIZE-INSTANCE (:AFTER) (QUEUE) 402000ADD3>

如果没有宏WITH-SLOTS，使用函数SLOT-VALUE，它看起来是这样的：

CL-USER 38 > (defmethod initialize-instance :after ((q queue) &rest initargs)
               (setf (slot-value q 'elements)
                     (make-array (slot-value q 'size) :initial-element nil)))

示例：

CL-USER 39 > (describe (make-instance 'queue :size 10))
#<QUEUE 402000BE0B> is a QUEUE
SIZE          10
ELEMENTS      #(NIL NIL NIL NIL NIL NIL NIL NIL NIL NIL)