使用 SPARQL 查询的 UNION 和交集

Question

我正在将用户定义的查询转换为SPARQL。例如，当用户说"abc"时，这意味着给我给定类型的所有节点，这些节点具有名为"abc"的属性。 作为扩展，如果用户说"abc 或 （pqr 和 lmn）"，我需要找到给定类型的所有节点，其中某些属性是"abc 或 （pqr 和 lmn）"。以下是我想出的查询：

SELECT DISTINCT ?node, ?type                                                 
WHERE                                                                          
{
  {                                                                              
    ?node a ?type .                                                          
    FILTER ( ?type != <sometype>)
  }
{           
  {                                                                              
    ?node ?reln0 ?obj0 .                                                     
    FILTER ( regex(str(?obj0), 'abc', "i") )                           
  }                                                                              
  UNION                                                                          
  {                                                                              
    {                                                                              
      ?node ?reln1 ?obj1 .                                                     
      FILTER ( regex(str(?obj1), 'pqr', "i") )                                
    }
    {                                                                             
      ?node ?reln2 ?obj2 .                                                     
      FILTER ( regex(str(?obj2), 'lmn', "i") )                               
    }                                                                              
  }
}                                                                              
}                                                                              
ORDER BY ?node

但它不会返回正确的结果。上面给出的查询有问题吗？我不想使用以下，因为我需要动态生成条件，并且每个子句都需要分开。

FILTER (regex(str(?obj2), 'abc', "i") || regex(str(?obj2), 'pqr', "i") && regex(str(?obj2), 'lmn', "i"))

Answer 1

我使您的查询具体如下（为第一个过滤器输入一个确定的类型）：

PREFIX : <http://example.org/>
SELECT DISTINCT ?node ?type                                                 
WHERE                                                                          
{
    {                                                                              
        ?node a ?type .                                                          
        FILTER ( ?type != :Type1 )
    }
    {           
        {                                                                              
            ?node ?reln0 ?obj0 .                                                     
            FILTER ( regex(str(?obj0), 'abc', "i") )                           
        }                                                                              
        UNION                                                                          
        {                                                                              
            {                                                                              
                ?node ?reln1 ?obj1 .                                                     
                FILTER ( regex(str(?obj1), 'pqr', "i") )                                
            }
            {                                                                             
                ?node ?reln2 ?obj2 .                                                     
                FILTER ( regex(str(?obj2), 'lmn', "i") )                               
            }                                                                              
        }
    }                                                                              
}                                                                              
ORDER BY ?node

然后，我生成了以下数据：

@prefix : <http://example.org/> .
:n1 a :Type2 ;    # keep
    :r0 :NodeABC .
:n2 a :Type2 ;
    :r0 :NodeBCD .
:n3 a :Type2 ;     # keep
    :r1 :NodePQR ;
    :r2 :NodeLMN .
:n4 a :Type2 ;
    :r1 :NodeQRS ;
    :r2 :NodeLMN .
:n5 a :Type2 ;
    :r1 :NodePQR ;
    :r2 :NodeMNO .
:n6 a :Type2 ;
    :r1 :NodeQRS ;
    :r2 :NodeMNO .

只应保留:n1和:n3。 我可以使用耶拿的命令行 ARQ 或基于 Redland 的 roqet 运行它，并且在这两种情况下我都会得到这些规则。

使用 ARQ：

$ arq --data data.n3 --query query.sparql
-----------------
| node | type   |
=================
| :n1  | :Type2 |
| :n3  | :Type2 |
-----------------
$ arq --version
Jena:       VERSION: 2.10.0
Jena:       BUILD_DATE: 2013-02-20T12:04:26+0000
ARQ:        VERSION: 2.10.0
ARQ:        BUILD_DATE: 2013-02-20T12:04:26+0000

与roqet ：

$ roqet query.sparql -D data.n3 -r table
roqet: Querying from file query.sparql
--------------------------------------------------------------
| node                       | type                          |
==============================================================
| uri<http://example.org/n1> | uri<http://example.org/Type2> |
| uri<http://example.org/n3> | uri<http://example.org/Type2> |
--------------------------------------------------------------
$ roqet -v
0.9.28