xslt foreach and break

Question

我知道在 xslt 中没有中断语句，也不知道如何解决我的问题。

例

      <tag name="param" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="param" />
      <tag name="Token" />
      <tag name="param" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="return"/>

参数

必须在下一个参数之前与所有令牌分组。我该怎么做？

输出必须如下所示：

param
    Token
    Token
    Token
param
    Token
param
    Token
    Token
    Token   

Answer 1

实现此目的的另一种方法是匹配"非参数"元素的键，按第一个最前面的参数元素对它们进行分组

<xsl:key 
  name="params" 
  match="tag[@name!='param']" 
  use="generate-id(preceding-sibling::tag[@name='param'][1])" />

然后，您将从匹配"参数"元素开始

<xsl:apply-templates select="tag[@name='param']" />

对于您匹配的每个标签，您可以使用键在组中选择关联的标签

<xsl:apply-templates select="key('params', generate-id())" />

请尝试以下 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text" />
   <xsl:key name="params" match="tag[@name!='param']" use="generate-id(preceding-sibling::tag[@name='param'][1])" />
   <xsl:template match="/*">
      <xsl:apply-templates select="tag[@name='param']" />
   </xsl:template>
   <xsl:template match="tag[@name='param']">
      <xsl:text>param&#10;</xsl:text> 
      <xsl:apply-templates select="key('params', generate-id())" />
   </xsl:template>
   <xsl:template match="tag">
      <xsl:value-of select="concat(' - ', @name, '&#10;')" />
   </xsl:template>
</xsl:stylesheet>

当应用于示例 XML 时（假设根元素），输出如下

param
 - Token
 - Token
 - Token
param
 - Token
param
 - Token
 - Token
 - Token
 - return

如果你不想要"return"元素，你可以添加另一个模板来匹配它，然后忽略它。

Answer 2

在 XSLT 2.0 中，使用 for-each-group 这很容易，但在 XSLT 1.0 中就不那么简单了。 区分组的一种方法是计算以下同级param标记：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:template match="/">
    <xsl:apply-templates select="*/tag[@name = 'param']" />
  </xsl:template>
  <xsl:template match="tag[@name = 'param']">
    <xsl:text>param&#x0a;</xsl:text>
    <xsl:apply-templates select="following-sibling::tag[@name = 'Token']
       [count(following-sibling::tag[@name='param'])
         = count(current()/following-sibling::tag[@name='param'])]" />
  </xsl:template>
  <xsl:template match="tag[@name = 'Token']">
    <xsl:text>&#x09;Token&#x0a;</xsl:text>
  </xsl:template>
</xsl:stylesheet>

在这里，我们选择的标签Token标签与我们开始的param标签数量相同，即在下一个参数之前出现的标签，这些标签与我们开始的标签数量param相同。 请注意，这是相当低效的，标签数量为 O（N²）。 更有效的方法是使用尾递归模板，让每个 Token "向前看"，看看它是否是下一个参数之前的最后一个 Token：

<xsl:template match="tag[@name = 'param']">
  <xsl:text>param&#x0a;</xsl:text>
  <xsl:apply-templates select="following-sibling::tag[1][@name = 'Token']" />
</xsl:template>
<xsl:template match="tag[@name = 'Token']">
  <xsl:text>&#x09;Token&#x0a;</xsl:text>
  <xsl:apply-templates select="following-sibling::tag[1][@name = 'Token']" />
</xsl:template>

在这里，param模板将模板应用于第一个后续令牌，令牌模板检查其第一个后续同级是否是另一个令牌，如果是，则递归应用模板。