用于选择唯一节点的 XPath 表达式

Question

我正在做一个项目，我必须将一些XML输入转换为一些XML输出，为此我使用的是XSLT版本1。

我正在处理的输入 XML 文件像 10k+ 行一样很大，但我花了大半个小时将其归结为以下代码片段，这涵盖了问题。

这是输入的 XML

<QueryInput >
  <Subject>
    <Content>
      <MunicipalityCode>0217</MunicipalityCode>
    </Content>
  </Subject>
  <QueryResultStep>
    <Multistep>
      <IterationResponse>
        <QueryResult>
          <Kommune>0217</Kommune>
        </QueryResult>
      </IterationResponse>
      <IterationResponse>
        <QueryResult>
          <Kommune>0217</Kommune>
        </QueryResult>
      </IterationResponse>
      <IterationResponse>
        <QueryResult>
          <Kommune>0223</Kommune>
        </QueryResult>
      </IterationResponse>
      <IterationResponse>
        <QueryResult>
          <Kommune>0223</Kommune>
        </QueryResult>
      </IterationResponse>
    </Multistep>
  </QueryResultStep>
</QueryInput>

输出 XML 应包含每个"Kommune"一次，删除重复项。为此，我编写了以下 XSLT 代码。

<?xml version="1.0" encoding="utf-8"?>
<xsl:transform version="1.0" xmlns:msxsl="urn:schemas-microsoft-com:xslt"
               xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
               xmlns:xsd="http://www.w3.org/2001/XMLSchema"
               xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
               exclude-result-prefixes="xsl xsi xsd">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="/">
    <QueryResult>
      <xsl:variable name="something">
        <KommuneCollection>
          <xsl:for-each select="QueryInput/QueryResultStep/Multistep/IterationResponse/QueryResult/Kommune[not(.=preceding::*)]">
            <NewKommune>
              <xsl:value-of select="."/>
            </NewKommune>
          </xsl:for-each>
        </KommuneCollection>
      </xsl:variable>
      <xsl:copy-of select="$something"/>
    </QueryResult>
  </xsl:template>
</xsl:transform>

这将产生以下（几乎正确）输出：

<KommuneCollection>
    <NewKommune>0223</NewKommune>
</KommuneCollection>

但应该产生

<KommuneCollection>
    <NewKommune>0217</NewKommune>
    <NewKommune>0223</NewKommune>
</KommuneCollection>

如果我删除输入 XML 中的<MunicipalityCode>0217</MunicipalityCode>，它会突然起作用 - 但我真的不明白为什么。不是为什么会发生这种情况，我也不知道如何解决这个问题。任何帮助将不胜感激！

编辑：通过将输入XML复制到Notepad++，安装XPathenizer工具，显示窗口并输入此XPath表达式QueryInput/QueryResultStep/Multistep/IterationResponse/QueryResult/Kommune[not(.=preceding::*)]，然后执行表达式，可以轻松复制该问题。然后可以在右侧看到结果。我怀疑问题出在 XSLT 中for-each标签中使用的 XPath 表达式上。

Answer 1

正如 michael.hor257k 所说，Muenchian 的分组对您很有帮助（处理大文件）。但是，以下是您当前尝试的正确版本：

<xsl:transform version="1.0" xmlns:msxsl="urn:schemas-microsoft-com:xslt" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" exclude-result-prefixes="xsl xsi xsd">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/">
    <QueryResult>
        <KommuneCollection>
            <xsl:for-each select="QueryInput/QueryResultStep/Multistep/IterationResponse/QueryResult/Kommune[not(. = preceding::QueryResult/Kommune )]">
                <NewKommune>
                    <xsl:value-of select="."/>
                </NewKommune>
            </xsl:for-each>
        </KommuneCollection>
    </QueryResult>
</xsl:template>
</xsl:transform>

注意：这种方式效率较低。当您使用Muenchian的分组时，您会感受到差异。

Answer 2

您的谓词本来可以工作，但未能包含"217"，因为/QueryInput/Subject/Content/MunicipalityCode恰好具有值"217"。

如果调整谓词筛选器以匹配前面的Kommune元素而不是任何前面的元素，则它将产生所需的结果：

[not(.=preceding::Kommune)]

但是，它不是很有效。如果您的文件很大，那么使用 xsl:key() 和 meunchian 方法的性能会更高。

<?xml version="1.0" encoding="utf-8"?>
<xsl:transform version="1.0" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema"
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    exclude-result-prefixes="xsl xsi xsd">
    <xsl:output method="xml" indent="yes"/>
    <xsl:key name="Kommune" match="Kommune" use="."/>
    <xsl:template match="/">     
        <QueryResult>
            <xsl:variable name="something">
                <KommuneCollection>
                    <xsl:for-each 
                          select="QueryInput/QueryResultStep/Multistep/
                                    IterationResponse/QueryResult/
                                    Kommune[generate-id(.) = 
                                            generate-id(key('Kommune',.)[1])]">
                        <NewKommune>
                            <xsl:value-of select="."/>
                        </NewKommune>
                    </xsl:for-each>
                </KommuneCollection>
            </xsl:variable>
            <xsl:copy-of select="$something"/>
        </QueryResult>
    </xsl:template>
</xsl:transform>