根据另一个元素值连接XSLT元素值

Question

我有以下XML:

<root>
    <attributes>
        <attribute_value>ID1</attribute_value>
        <attribute_name>id</attribute_name>
    </attributes>
    <attributes>
        <attribute_value>ID2</attribute_value>
        <attribute_name>id</attribute_name>
    </attributes>
    <attributes>
        <attribute_value>some-link</attribute_value>
        <attribute_name>link</attribute_name>
    </attributes>
</root>

我想遍历该文件，并使用XSLT(1.0或2.0)基于"attribute_name"值连接所有"attribute_value"值。在本例中，输出将是:

<root>
    <element name="id" value="ID1"/>
    <element name="ids" value="ID1,ID2"/>
    <element name="link" value="some-link"/>
</root>

"id"元素应该包含遇到的第一个值，"ids"元素应该包含连接的值。如何才能做到这一点?我有一个可用的XSLT，在其中使用标记并遍历所有属性，但无法解决这个问题。

下面是我当前的XSLT:

<?xml version="1.0" encoding="ISO-8859-1"?>
    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
        <xsl:output method="xml" version="1.0" indent="yes"/>
        <xsl:template match="root">
            <root>
                <xsl:for-each select="attributes">  
                    <xsl:variable name="attribute_name" select="attribute_name"/>
                    <xsl:variable name="attribute_value" select="attribute_value"/>
                    <xsl:if test="$attribute_name = 'link'">
                        <element name="link">
                            <xsl:attribute name="value"><xsl:value-of select="$attribute_value" /></xsl:attribute>
                        </element>
                    </xsl:if>
                </xsl:for-each>
            </root>
        </xsl:template>
    </xsl:stylesheet>

Answer 1

由于使用的是XSLT 2.0，因此可以在这里使用xsl:for-each-group

<xsl:for-each-group select="attributes" group-by="attribute_name">  

然后输出第一个元素，可以这样做:

 <element name="{attribute_name}" value="{attribute_value}" />

(注意使用属性值模板来简化属性的创建)

然后，如果组中有多个元素，您可以创建像这样的连接版本:

<element name="{@attribute_name}s" value="{string-join(current-group()/attribute_value, ',')}" />

试试这个XSLT

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" indent="yes"/>
    <xsl:template match="root">
        <root>
            <xsl:for-each-group select="attributes" group-by="attribute_name">  
                <element name="{attribute_name}" value="{attribute_value}" />
                <xsl:if test="current-group()[2]">
                    <element name="{@attribute_name}s" value="{string-join(current-group()/attribute_value, ',')}" />
                </xsl:if>
            </xsl:for-each-group>
        </root>
    </xsl:template>
</xsl:stylesheet>