XSLT:连接一系列的范围(如果它们是连续的)

Question

我有一系列整数范围:

<ranges>
    <range>
        <start>1</start>
        <end>10</end>
    </range>
    <range>
        <start>11</start>
        <end>55</end>
    </range>
    <range>
        <start>56</start>
        <end>60</end>
    </range>
    <range>
        <start>65</start>
        <end>70</end>
    </range>
</ranges>

我想压缩范围，当它们是连续的。对于上面的XML，我要寻找的输出是:

<ranges>
    <range>
        <start>1</start>
        <end>60</end>
</range>
    <range>
        <start>65</start>
        <end>70</end>
    </range>

这在XSLT中是可能的吗?

Answer 1

尝试:

<xsl:for-each-group select="range" 
  group-starting-with="*[start != preceding-sibling::range[1]/end + 1]">
  <range>
    <start><xsl:value-of select="start"/></start>
    <end><xsl:value-of select="current-group()[last()]/end"/></end>
  </range>
</xsl:for-each-group>

不是测试。

Answer 2

试试这样做。(有点直接，但应该这样做):

<?xml version="1.0"?>
<xsl:stylesheet
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   version="1.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="range" mode="end" >
        <xsl:choose>
            <xsl:when test="../range[start =current()/end+1]">
                <xsl:apply-templates select="../range[start =current()/end+1]" mode ="end" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="end"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="range" mode="start">
        <xsl:copy>
            <xsl:copy-of select="start"/>
            <xsl:apply-templates select="." mode="end" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="/*">
        <xsl:for-each select="range">
            <xsl:sort select="start"/>
            <xsl:if test="not(../range[current()/start = end+1]) or position() = 1" >
                <xsl:apply-templates select="." mode="start"/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>   
</xsl:stylesheet>

这将生成以下输出:

<?xml version="1.0"?>
<range>
  <start>1</start>
  <end>60</end>
</range><range>
  <start>65</start>
  <end>70</end>
</range>