在Common Lisp中对宏使用循环生成类槽

Question

在cls上创建类时，我多次遇到相同的模式:

(defclass class-name () 
  ((field-1
      :initarg field-1
      :initform some-value
      :accessor field-1)
   (field-2
      :initarg field-2
      :initform another-value
      :accessor field-2)
   (...)
   (field-n
      :initarg field-n
      :initform n-value
      :accessor field-n)))

(这是否是一个好的设计，我将随着时间的推移而学习)

我试着用一个宏来解决这个问题，所以我可以调用，说:

(defclass-with-accessors 'class-name
   (('field-1 some-value)
    ('field-2 another-value)
    (...)
    ('field-n n-value)))

我的第一个处理(现在忽略卫生)是将其分成两个宏:一个用于生成每个字段，另一个用于生成类本身。

使访问器字段看起来正确的宏:

(defmacro make-accessor-field (name form)
  `(,name
   :initarg ,(make-keyword name)
   :initform ,form
   :accessor ,name))

但是我没有得到主宏的权利。我的第一个尝试是:

(defmacro defclass-with-accessors (name body)
  `(defclass ,name () (
     ,(loop for my-slot in body collect
       (make-accessor-field (car my-slot) (cadr my-slot)))))

但这是无效的，SBCL在defmacro评估时给我以下错误:

; in: DEFMACRO DEFCLASS-WITH-ACCESSORS
;     (MAKE-ACCESSOR-FIELD (CAR MY-SLOT) (CADR MY-SLOT))
; 
; caught ERROR:
;   during macroexpansion of (MAKE-ACCESSOR-FIELD (CAR MY-SLOT) (CADR MY-SLOT)).
;   Use *BREAK-ON-SIGNALS* to intercept.
;   
;    The value (CAR MY-SLOT)
;    is not of type
;      (OR (VECTOR CHARACTER) (VECTOR NIL) BASE-STRING SYMBOL CHARACTER).
; 
; compilation unit finished
;   caught 1 ERROR condition
STYLE-WARNING:
   redefining COMMON-LISP-USER::DEFCLASS-WITH-ACCESSORS in DEFMACRO

到底发生了什么?当slot甚至没有定义时，编译器如何告诉(car slot)的类型?我怎样才能正确地定义这个宏?

Answer 1

的基本错误

这个宏是错误的，因为它不应该是一个宏:

(defmacro make-accessor-field (name form)
  `(,name
   :initarg ,(make-keyword name)
   :initform ,form
   :accessor ,name))

宏表单应该展开为代码。这个宏将表单展开为用于槽描述的列表。槽位描述不是代码，而是defclass槽位列表的一部分。因此，您不能使用这样的宏，因为返回的值应该是代码，而不是插槽描述列表。

通常不会在宏名中使用MAKE-。这更像是一种惯例。MAKE-SOMETHING应该是函数。当你make某事时，在运行时创建了一些东西，因此它应该是一个函数。有时人们也想将make应用到一个列表中，然后再一次，一个函数是首选。

这也是错误的，因为有一个符号以圆括号作为其名称:

(defmacro defclass-with-accessors (name body)
  `(defclass ,name () (    ;  <-  what is this?
     ,(loop for my-slot in body collect
       (make-accessor-field (car my-slot) (cadr my-slot)))))

这段代码也不是一个好主意，因为引号是没有用的:

(defclass-with-accessors 'class-name
   (('field-1 some-value)
    ('field-2 another-value)
    (...)
    ('field-n n-value)))

如果你看defclass，它不需要引号。因此，在您的defclass变体中，也不应该有引号。

让我们试着改进它

示例表单来自一些假想的代码库:

(defclass-with-accessors foo
   ((bar 10)
    (baz (sin pi)))

MAKE-ACCESSOR-FIELD现在是一个函数:

(defun make-accessor-field (name form)
  `(,name
    :initarg  ,(intern (symbol-name name) "KEYWORD")
    :initform ,form
    :accessor ,name))

新DEFCLASS-WITH-ACCESSORS:

(defmacro defclass-with-accessors (name slot-descriptions)
  `(defclass ,name ()
     ,(loop for (slot-name form) in slot-descriptions
            collect (make-accessor-field slot-name form))))

让我们检查一下扩展:

macroexpand-1在顶层展开一次表单，pprint以某种自动格式化的方式打印s表达式:

CL-USER 12 > (pprint (macroexpand-1 '(defclass-with-accessors foo
                                         ((bar 10)
                                          (baz (sin pi))))))
(DEFCLASS FOO
          NIL
          ((BAR :INITARG :BAR :INITFORM 10 :ACCESSOR BAR)
           (BAZ :INITARG :BAZ :INITFORM (SIN PI) :ACCESSOR BAZ)))

看起来好。