F#:有没有办法扩展monad关键字列表

Question

在F#monad内部，如果说let!，编译器会将其转换为您在monad生成器上定义的Bind成员。

现在我看到了Query monad，如MSDN上所示，您可以说：

query {
    for student in db.Student do
    select student
    count
}

并且例如select和count将被转换为QueryBuilder成员Linq.QueryBuilder.Select和Linq.QueryBuilder.Count。

我的问题是，这种关键字到成员的映射是通过F#编译器硬连接的，还是可扩展的？例如，我可以说这样的话吗：

FooMonadBuilder() {
    bar
}

并以某种方式告诉F#编译器bar映射到FooMonadBuilder.Bar()方法？

Answer 1

在F#2.0（即Visual Studio 2010）中，没有办法扩展关键字列表（除了Ramon的扩展）。但是，F#3.0（Visual Sutdio 11）中的查询机制是可扩展的，您可以定义自己的关键字，类似于select和count。

以下是一个基本示例，它定义了类似seq的构建器，其中包含reverse关键字：

type SeqBuilder() =
    // Standard definition for 'for' and 'yield' in sequences
    member x.For (source : seq<'T>, body : 'T -> seq<'R>) =
      seq { for v in source do yield! body v }
    member x.Yield item =
      seq { yield item }
    // Define an operation 'select' that performs projection
    [<CustomOperation("select")>]
    member x.Select (source : seq<'T>, [<ProjectionParameter>] f: 'T -> 'R) : seq<'R> =
        Seq.map f source
    // Defines an operation 'reverse' that reverses the sequence    
    [<CustomOperation("reverse", MaintainsVariableSpace = true)>]
    member x.Expand (source : seq<'T>) =
        List.ofSeq source |> List.rev
let mseq = SeqBuilder()

其工作原理的详细信息尚未记录在案，但CustomOperation属性表示，该操作应被视为一种特殊语法（您可以设置各种属性来指定其行为方式——MaintainsVariableSpace意味着它不会更改序列内的值）。Projectionparameter属性指定关键字后面的表达式应隐式转换为函数。

现在，mseq构建器同时支持select和reverse:

let q = mseq { for i in 1 .. 10 do
               select (i + 100)
               reverse }

Answer 2

简短回答：没有。

我已经扩展了编译器来支持它，欢迎您阅读我的博客文章http://ramon.org.il/wp/2011/04/taking-computation-expressions-one-step-further/