xsl:条件检查

Question

>我有一个输入XML，如下所示

<testing>
<subject ref="yes">
 <firstname>
    tom
 </firstname>
</subject>
<subject ref="no">
 <firstname>
    sam
</firstname>
</subject>
</testing>

我期待我的输出应该是。

如果主题的引用为是。 我将获得名称值。否则，如果引用（否）我不会得到元素

<testing>
<firstname>
   tom
</firstname>
</testing>

请在这里指导我。

Answer 1

这可以通过在身份转换之上构建来实现。首先，您需要一个模板来忽略@ref为"否"的主题元素

<xsl:template match="subject[@ref='no']" />

对于@ref为"是"的主题元素，您有另一个模板来仅输出其子模板

<xsl:template match="subject[@ref='yes']">
   <xsl:apply-templates select="node()"/>
</xsl:template>

事实上，如果@ref只能是"是"或"否"，您可以将此模板匹配简化为仅<xsl:template match="subject">因为这将匹配所有没有"否"@ref的元素

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:template match="subject[@ref='no']" />
   <xsl:template match="subject">
      <xsl:apply-templates select="node()"/>
   </xsl:template>
   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

应用于示例 XML 时，输出如下

<testing>
<firstname> tom </firstname>
</testing>

Answer 2

这个简短的转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="/*">
  <testing><xsl:apply-templates/></testing>
 </xsl:template>
 <xsl:template match="subject[@ref='yes']">
  <xsl:copy-of select="node()"/>
 </xsl:template>
 <xsl:template match="subject"/>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<testing>
    <subject ref="yes">
        <firstname>
         tom
     </firstname>
    </subject>
    <subject ref="no">
        <firstname>
         sam
     </firstname>
    </subject>
</testing>

产生所需的正确结果：

<testing>
   <firstname>
         tom
     </firstname>
</testing>

Answer 3

试试这个：

<testing>
  <xsl:if test="testing/subject/@ref = 'yes'">
    <firstname>
      <xsl:value-of select="testing/subject/firstname" />
    </firstname>
  </xsl:if>
</testing>

我希望这应该在 xslt 中工作