来自.gz文件日志的TXT列表中的Big Grep

Question

这是我的问题（对我来说实际上是一个大问题）。

我有一个TXT文件，其中有1.130.395行，如下一个示例：

10812
10954
10963
11070
11099
10963
11070
11099
betti.bt
betti12
betti1419432307
19442407
19451970
19461949

我有2000 .gz日志文件。

我需要在所有.gz文件上执行.txt文件的每一行。

这是GZ文件内容的一个示例，一个示例行：

time=2019-02-28 00:03:32,299|requestid=30ed0f2b-9c44-47d0-abdf-b3a04dbb560e|severity=INFO |severitynumber=0|url=/user/profile/oauth/{token}|params=username:juvexamore,token:b73ad88b-b201-33ce-a924-6f4eb498e01f,userIp:10.94.66.74,dtt:No|result=SUCCESS
time=2019-02-28 00:03:37,096|requestid=8ebca6cd-04ee-4818-817d-30f78ee95731|severity=INFO |severitynumber=0|url=/user/profile/oauth/{token}|params=username:10963,token:1d99be3e-325f-3982-a668-30494cab9a96,userIp:10.94.66.74,dtt:No|result=SUCCESS

TXT文件包含用户名。如果存在使用"配置文件"参数和"结果=成功"的URL，我需要在GZ文件中搜索。

如果发现了某些内容，请仅写入日志文件： username found; name of the log file in which it was found

可以做某事吗？我知道我需要使用ZGREP命令，但是有人可以帮助我。...可以自动化该过程以使其开始？

谢谢所有

Answer 1

我会做（未经测试）：

zgrep -H 'url=/user/profile/oauth/{token}|params=username:.*result=SUCCESS' *.gz |
awk -F'[=:,]' -v OFS=';' 'NR==FNR{names[$0];next} $12 in names{print $12, $1}' names.txt - |
sort -u

，或可能更有效地效率，因为它删除了ZGREP输出的每行输出的NR==FNR测试：

zgrep -H 'url=/user/profile/oauth/{token}|params=username:.*result=SUCCESS' *.gz |
awk -F'[=:,]' -v OFS=';' '
    BEGIN {
        while ( (getline line < "names.txt") > 0 ) {
            names[line]
        }
        close("names.txt")
    }
    $12 in names{print $12, $1}' |
sort -u

如果给定的用户名只能在给定的日志文件中出现一次，或者您实际需要多个出现来产生多个输出行，则不需要最终的| sort -u。

Answer 2

使用getline重写。它读取和哈希 file.txt用户名，然后读取为参数的gunzips gzips， split s，直到使用 username:获取字段，提取实际的用户名并从哈希搜索。未正确测试等。等等。标准免责声明。让我知道它是否有效：

$ cat script.awk
BEGIN{
    while (( getline line < ARGV[1]) > 0 ) {       # read the username file
        a[line]                                    # and hash to a
    }
    close(ARGV[1])
    for(i=2;i<ARGC;i++) {                          # read all the other files
        cmd = "gunzip --to-stdout " ARGV[i]        # form uncompress command
        while (( cmd | getline line ) > 0 ) {      # read line by line
            m=split(line,t,"|")                    # split at pipe
            if(t[m]!="result=SUCCESS")             # check only SUCCESS records
                continue
            n=split(t[6],b,/[=,]/)                 # username in 6th field
            for(j=1;j<=n;j++)                      # split to find it, set to u var:
                if(match(b[j],/^username:/)&&((u=substr(b[j],RSTART+RLENGTH)) in a)) {
                    print u,"found in",ARGV[i]     # output if found in a hash
                        break                      # exit for loop once found
                }
        }
        close(cmd)
    }
}

运行它（使用相同数据的2个副本）：

$ awk -f script.awk file.txt log-0001.gz log-0001.gz
10963 found in log-0001.gz
10963 found in log-0001.gz