维基数据按项目查询识别

Question

我想按项目标识查询给定城市的翻译。为此，我在卡尔斯鲁厄的IF上查询属性P31

这是我的查询

 SELECT DISTINCT ?city ?label ?population WHERE {
  ?city (wdt:P31/wdt:P279*) wd:Q515. // is city
  ?city wdt:P31 wd:Q1040. //is karlsruhe
  ?city wdt:P1082 ?population.
  ?city rdfs:label ?label.
  FILTER(((LANG(?label)) = "de") || ((LANG(?label)) = "en") || ((LANG(?label)) = "it") || ((LANG(?label)) = "ru") || ((LANG(?label)) = "ro") || ((LANG(?label)) = "tr") || ((LANG(?label)) = "pl") || ((LANG(?label)) = "fr") || ((LANG(?label)) = "es") || ((LANG(?label)) = "hr"))
}

但我没有得到任何结果。

我做错了什么？

Answer 1

简而言之，问题是卡尔斯鲁厄不是卡尔斯鲁厄。请仔细阅读 wdt：P31 的定义。

您的查询应为：

SELECT DISTINCT ?city ?label ?population WHERE {
  VALUES (?city) { (wd:Q1040) }      # is Karlsruhe
  ?city (wdt:P31/wdt:P279*) wd:Q515  # is a city
  OPTIONAL { ?city wdt:P1082 ?population } 
  ?city rdfs:label ?label
  FILTER(LANG(?label) IN ("de", "en", "it", "ru", "ro", "tr", "pl", "fr", "es", "hr"))
}

---

为了更好地理解，可以这样重写上面的查询：

SELECT DISTINCT ?city ?label ?population WHERE {
  FILTER(?city IN (wd:Q1040))        # is Karlsruhe
  ?city (wdt:P31/wdt:P279*) wd:Q515  # is a city
  OPTIONAL { ?city wdt:P1082 ?population } 
  ?city rdfs:label ?label
  FILTER(LANG(?label) IN ("de", "en", "it", "ru", "ro", "tr", "pl", "fr", "es", "hr"))
}

在RDFS++蕴涵下，人们甚至会这样写：

SELECT DISTINCT ?city ?label ?population WHERE {
  ?city owl:sameAs wd:Q1040   # is Karlsruhe
  ?city wdt:P31 wd:Q515       # is a city
  OPTIONAL { ?city wdt:P1082 ?population } 
  ?city rdfs:label ?label
  FILTER(LANG(?label) IN ("de", "en", "it", "ru", "ro", "tr", "pl", "fr", "es", "hr"))
}