嵌套元素的多个属性

Question

我想将下面的示例段转换为多个元素。

<para font="Times" size="12" face="Bold Italic">This is some text.</para>
<para font="Times" size="12" face="Bold">This is some more text.</para>

我想将其转换为这样的东西：

<para>
   <font name="Times" size="12">
       <b>
           <i>This is some text.</i>
       </b>
    </font>
</para>
<para>
   <font name="Times" size="12">
       <b>This is some text.</b>
    </font>
</para>

是否可以在不使用所有<xsl:choose>块的母亲的情况下进行此操作。以上是具有更多属性和属性值的简单示例。

我正在使用XSLT 1.0（XSLTPROC）

Answer 1

我认为您可能仍然会以 XSL：选择在此处映射诸如" bold"one_answers" Italic"之类的单词到" b"的元素名称和"我"

因此，您将从匹配 @face 属性的模板开始

<xsl:template match="@face" name="face">
    <xsl:param name="face" select="." />

您将提取使用一些简单的字符串处理

处理的第一个面部名称

<xsl:variable name="facename" select="substring-before(concat($face, ' '), ' ')" />

（这里的contat是在参数中允许一个单词）

然后您可以将映射到SO

之类的元素名称

    <xsl:variable name="element">
        <xsl:choose>
            <xsl:when test="$facename = 'Bold'">b</xsl:when>
            <xsl:when test="$facename = 'Italic'">i</xsl:when>
        </xsl:choose>
    </xsl:variable>

话虽如此，您可以从理论上将映射维护在单独的XML文件中，并使用 document 函数查找它们。

最后，您将拥有一个 XSL：选择以输出元素，如果找到了元素，或处理父元素的孩子

    <xsl:choose>
        <xsl:when test="$element != ''">
            <xsl:element name="{$element}">
                <xsl:call-template name="face">
                    <xsl:with-param name="face" select="normalize-space(substring-after($face, $facename))" />
                </xsl:call-template>
            </xsl:element>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates select="../node()" />
        </xsl:otherwise>
    </xsl:choose>

尝试此XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output indent="yes"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*[@font]">
        <xsl:copy>
            <font>
                <xsl:apply-templates select="@*[name() != 'face']"/>
                <xsl:apply-templates select="@face" />
            </font>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@face" name="face">
        <xsl:param name="face" select="." />
        <xsl:variable name="facename" select="substring-before(concat($face, ' '), ' ')" />
        <xsl:variable name="element">
            <xsl:choose>
                <xsl:when test="$facename = 'Bold'">b</xsl:when>
                <xsl:when test="$facename = 'Italic'">i</xsl:when>
            </xsl:choose>
        </xsl:variable>
        <xsl:choose>
            <xsl:when test="$element != ''">
                <xsl:element name="{$element}">
                    <xsl:call-template name="face">
                        <xsl:with-param name="face" select="normalize-space(substring-after($face, $facename))" />
                    </xsl:call-template>
                </xsl:element>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates select="../node()" />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Answer 2

假设@face的值实际上对应于输出中的元素名称（几个人已经对此评论），您可以做类似的事情。

递归命名的模板实际上将@face属性的内容显示为确定嵌套序列。

样式表

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exsl="http://exslt.org/common"
    extension-element-prefixes="exsl">
    <xsl:strip-space elements="*"/>
    <xsl:output omit-xml-declaration="yes" indent="yes" />
    <xsl:template match="/root">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="para">
        <xsl:copy>
            <font name="{@font}" size="{@size}">
                        <xsl:call-template name="tokenize">
                            <xsl:with-param name="string" select="@face"/>
                            <xsl:with-param name="delim" select="' '"/>
                        </xsl:call-template>
            </font>
        </xsl:copy>
    </xsl:template>
    <xsl:template name="tokenize">
      <xsl:param name="string" />
      <xsl:param name="delim" />
      <xsl:choose>
        <xsl:when test="contains($string, $delim)">
          <xsl:element name="{substring-before($string,$delim)}">
            <xsl:call-template name="tokenize">
            <xsl:with-param name="string" select="substring-after($string, $delim)" />
            <xsl:with-param name="delim" select="$delim" />
          </xsl:call-template>
          </xsl:element>
        </xsl:when>
        <xsl:otherwise>
          <xsl:element name="{$string}">
            <xsl:apply-templates/>
          </xsl:element>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

它处理@face内的任意数量的令牌。例如，当应用于以下输入时：

<?xml version="1.0"?>
<root>
    <para font="Times" size="12" face="i b u s">This is some text.</para>
    <para font="Times" size="12" face="i b">This is some more text.</para>
</root>

结果是：

<root>
   <para>
      <font name="Times" size="12">
         <i>
            <b>
               <u>
                  <s>This is some text.</s>
               </u>
            </b>
         </i>
      </font>
   </para>
   <para>
      <font name="Times" size="12">
         <i>
            <b>This is some more text.</b>
         </i>
      </font>
   </para>
</root>

Answer 3

我写了一个样式表，其中包含一个表格，您可以在其中添加样式并将其与标签相关联。例如，您可以将<b>替换为<strong>或添加新的<tag name="strike" style="Strike-through"/>。该表可以通过$tags变量访问，并用于选择与face属性样式名称相对应的标签。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:my="my-namespace" exclude-result-prefixes="my" version="1.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    <my:styles>
        <tag name="b" style="Bold"/>
        <tag name="i" style="Italic"/>
        <tag name="u" style="Underline"/>
    </my:styles>
    <xsl:variable name="tags" select="document('')//tag" />
    <xsl:template match="/">
        <xsl:apply-templates select="document/para" mode="initial" />
    </xsl:template>
    <xsl:template match="para" mode="initial">
        <xsl:copy>
            <font name="{@font}" size="{@size}">
                <xsl:choose>
                    <xsl:when test="@face">
                        <xsl:call-template name="add-style">
                            <xsl:with-param name="styles" select="concat(@face,' ')"/>
                        </xsl:call-template>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="."/>
                    </xsl:otherwise>
                </xsl:choose>
            </font>
        </xsl:copy>
    </xsl:template>
    <xsl:template name="add-style">
        <xsl:param name="styles"/>
        <xsl:param name="current-style" select="substring-before($styles, ' ')"/>
        <xsl:message>value:<xsl:value-of select="$styles"/>:</xsl:message>
        <xsl:if test="$current-style">
            <xsl:element name="{$tags[@style = $current-style]/@name}">
                <xsl:call-template name="add-style">
                    <xsl:with-param name="styles" select="substring-after($styles, ' ')"/>
                </xsl:call-template>
                <xsl:if test="not(contains(substring-after($styles, ' '), ' '))">
                    <xsl:value-of select="." />
                </xsl:if>
            </xsl:element>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

如果将其用作输入：

<document>
    <para font="Times" size="12" face="Bold Italic">This is some text.</para>
    <para font="Times" size="12" face="Bold">This is some more text.</para>
    <para font="Times" size="12" face="Italic Bold Underline">This is some text 3.</para>
    <para font="Times" size="12" face="Italic">This is some more text 4.</para>
    <para font="Times" size="12">This is some more text 4.</para>
</document>

您得到此结果：

<para>
   <font name="Times" size="12">
      <b>
         <i>This is some text.</i>
      </b>
   </font>
</para>
<para>
   <font name="Times" size="12">
      <b>This is some more text.</b>
   </font>
</para>
<para>
   <font name="Times" size="12">
      <i>
         <b>
            <u>This is some text 3.</u>
         </b>
      </i>
   </font>
</para>
<para>
   <font name="Times" size="12">
      <i>This is some more text 4.</i>
   </font>
</para>
<para>
   <font name="Times" size="12">This is some more text 4.</font>
</para>

我没有使用大型选择，但是我不得不使用一个选择来解决face属性可能不存在的情况。

，如果face属性中有额外的空格，它将失败，因为我使用空格（甚至添加一个）来控制递归。但这可以用normalize-space()进行修复。