我需要了解如何在使用XSL选择的子元素中获得具有类似值的并行元素的位置。我列出了带有特定引用的项目行作为子元素，然后我有子项目行，它们应该根据子元素值链接到项目行中。子项目行应指示具有类似参考的项目行的位置
我尝试过几种不同的方法，括号[]中有不同的条件，但到目前为止运气不佳。我只能使用xslt 1.0
我有这样结构的xml：
<goods>
<item>
<ref>a</ref>
</item>
<item>
<ref>b</ref>
</item>
<item>
<ref>c</ref>
</item>
<item>
<ref>d</ref>
</item>
<subitem>
<subref>c</subref>
</subitem>
<subitem>
<subref>a</subref>
</subitem>
</goods>
和我的xsl(1.0(:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
<xsl:output method="text" version="1.0" encoding="ISO-8859-1" indent="yes"/>
<xsl:template match="/">
<xsl:call-template name="Line"/>
</xsl:template>
<xsl:template name="Line">
<xsl:for-each select="goods/item">
<xsl:value-of select="position()"/>
<xsl:text>;</xsl:text>
<xsl:value-of select="ref"/>
<xsl:text>
</xsl:text>
</xsl:for-each>
<xsl:for-each select="goods/subitem">
<xsl:text>0;</xsl:text>
<xsl:value-of select="subref"/>
<xsl:text>;</xsl:text>
here would be some kind of conditional preceeding select needed
<xsl:text>
</xsl:text>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
所需输出为：
1;a
2;b
3;c
4;d
0;c;3
0;a;1
其中最后2行是子项，最后一个数字应该告诉我相同引用所在的项元素的位置。在示例中，引用"c"位于位置为3的项元素内部(第三个项元素在子元素"ref"中有"c"(，因此子引用值为"c"的子项应该链接到示例中的项位置3。
每个子项行也是如此：所有子项/子项=a的行都应该有位置1，所有"b"的行都有位置2等等。
这里有一种方法：
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:key name="item" match="item" use="ref" />
<xsl:template match="/goods">
<xsl:for-each select="item">
<xsl:value-of select="position()" />
<xsl:text>;</xsl:text>
<xsl:value-of select="ref"/>
<xsl:text>
</xsl:text>
</xsl:for-each>
<xsl:for-each select="subitem">
<xsl:text>0;</xsl:text>
<xsl:value-of select="subref"/>
<xsl:text>;</xsl:text>
<xsl:value-of select="count(key('item', subref)/preceding-sibling::item) +1" />
<xsl:text>
</xsl:text>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
注意，这假设每个subref都有一个具有匹配ref值的对应item。