如何检查控件何时完全初始化

Question

如何检查控件是否完全初始化?
考虑下面的代码(我知道这样做是非常糟糕的做法，请把它作为一个例子)

type
  TForm1 = class(TForm)
    Memo1: TMemo;
  private
    procedure WndProc(var Message: TMessage); override;
  public
    { Public declarations }
  end;
procedure TForm1.WndProc(var Message: TMessage);
begin
{  
   I'd like to log the messages to the memo as soon 
   as it's possible so I need to find out how to
   check if the memo box is ready to use; the following
   code stuck the application, so that the form is not
   even displayed. How would you fix this code except
   "avoid using of component access in window proc" ?
}
  if Assigned(Memo1) then
    if Memo1.HandleAllocated then
      Memo1.Lines.Add('Message: ' + IntToStr(Message.Msg));
  inherited WndProc(Message);
end;

注:我知道OutputDebugString:-)
谢谢!

Answer 1

你的问题把我弄糊涂了。当你说:

将消息记录到memo

您的意思是您想要通过向备忘中写入文本来将消息记录到表单中。

这种方法充满了危险，因为当您写入备忘录时，表单会收到发送的消息，这导致您写入备忘录，并且堆栈溢出是不可避免的后果。

我设法使你的想法在可重入性保护中起作用。我还介绍了一个暂态非可视字符串列表，用于捕获在控件准备显示消息之前传递的任何消息。一旦您引入了这一点，那么您就不再需要担心找到最安全的添加备忘的精确最早时刻。

unit LoggingHack;
interface
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;
type
  TLoggingForm = class(TForm)
    Memo1: TMemo;
  private
    FLog: TStringList;
    FLogging: Boolean;
  protected
    procedure WndProc(var Message: TMessage); override;
  public
    destructor Destroy; override;
  end;
var
  LoggingForm: TLoggingForm;
implementation
{$R *.dfm}
{ TLoggingForm }
destructor TLoggingForm.Destroy;
begin
  FreeAndNil(FLog);
  inherited;
end;
procedure TLoggingForm.WndProc(var Message: TMessage);
var
  Msg: string;
begin
  if not FLogging then begin
    FLogging := True;
    Try
      Msg := IntToStr(Message.Msg);
      if Assigned(Memo1) and Memo1.HandleAllocated then begin
        if Assigned(FLog) then begin
          Memo1.Lines.Assign(FLog);
          FreeAndNil(FLog);
        end;
        Memo1.Lines.Add(Msg);
      end else if not (csDestroying in ComponentState) then begin
        if not Assigned(FLog) then begin
          FLog := TStringList.Create;
        end;
        FLog.Add(Msg);
      end;
    Finally
      FLogging := False;
    End;
  end;
  inherited;
end;
end.
end;

这个故事的寓意是，您应该使用一个更合适的日志框架，使不会与您试图记录的内容交互。