如何在ejb中使发送者id (From)匿名

Question

我有一些用户，他们可以匿名聊天。他们正在进行一对一的谈话。假设我想加密发送者的用户名。我怎样才能做到这一点呢?

到目前为止我做了什么:

start(_Host, _Opts) ->
   ejabberd_hooks:add(filter_packet, global, ?MODULE, on_filter_packet, 0).
on_filter_packet({From, To, XML} = Packet) ->
        ?INFO_MSG("Packet From intercepted ~p", [From] ),
        Packet.

在这段代码中，它返回的是数据包，我可以在该函数中更改数据包。

我如何改变From，使它反映在客户端。

这是日志中的From:

{jid,<<"username">>,<<"domain.com">>,<<"1960117812133817321731161">>,<<"username">>,<<"domain.com">>,<<"1960117812133817321731161">>}

提前致谢

Answer 1

首先，您的实现存在一个主要问题。您正在尝试转换所有数据包，而不仅仅是message数据包。您这样做的方式是，您将通过重写iq和presence数据包来破坏路由

这里是一个工作模块，基本上取代了消息的from。我使用哈希对发件人进行"编码"，并使用户名"永久"，以便来自同一个人的所有消息将出现在单个对话中。但是，可以随意替换为您选择的算法:

%% To add in ejabberd modules configuration section:
%%   mod_replace_from: {}
-module(mod_replace_from).
-behaviour(gen_mod).
-export([start/2, stop/1]).
-export([on_filter_packet/1]).
-include("jlib.hrl").
-include("logger.hrl").
start(_Host, _Opts) ->
    ejabberd_hooks:add(filter_packet, ?MODULE, on_filter_packet, 50),
    ok.
stop(_Host) ->
    ejabberd_hooks:delete(filter_packet, ?MODULE, on_filter_packet, 50),
    ok.
on_filter_packet({From, To, #xmlel{name = <<"message">>} = XML}) ->
    ?INFO_MSG("Packet From intercepted ~p ~p", [From, XML]),
    NewFrom = replace_jid_user(From),
    {NewFrom, To, XML};
on_filter_packet(Packet) ->
    Packet.
replace_jid_user(JID) ->
    {U, S, R} = split_jid(JID),
    Hash = integer_to_binary(erlang:phash2(U)),
    jlib:make_jid(Hash,S,R).
%% Will be added to jlib.erl
%% This is the reverse of make_jid/3
-spec split_jid(jid()) -> {binary(), binary(), binary()} | error.                              
split_jid(#jid{user = U, server = S, resource = R}) ->
    {U, S, R};
split_jid(_) ->
    error.

这是一个基本的实现，因为虽然它回答了问题，但它远远不是匿名聊天的完整解决方案。例如，您将需要处理算法来实现数据包的路由，以允许人们回复并确保数据包将到达原始匿名发送者。我相信will在未来的道路上会面临更多的挑战。

然而，这解决了这个问题，并说明了ejabberd中的From JID操作。