将clojure中的闭包恢复或重置为初始状态的任何快速方法

Question

是否有快速恢复或重置闭包到初始状态的方法?例如，在下面的函数中，我如何重置与myClosureFn相关的stat1和stat2的值为1?

这个问题的上下文:我在不同的函数中使用下面的结构，其中一个函数可能会"弄乱"与闭包相关的值。所以我需要重置/恢复它的初始状态，以便将它再次传递到另一个函数。

(def myClosureFn 
  (let [stat1 (atom 1)
        stat2 (atom 1)
        ;..stat3 stat4 ...
        ]
    (fn [m]
      (swap! stat1 inc)
      (reset!   stat2 (* 2 m))
      [@stat1  @stat2])))
(myClosureFn 1) ;--> [2 2] 
(myClosureFn 2) ;--> [3 4]
(myClosureFn 2) ;--> [4 4]
(myClosureFn 3) ;--> [5 6]
;...
; how to get [ 1 1 ] back to myClosureFn ?

Answer 1

与其显式地重新设置与函数相关的状态，不如考虑使用高阶函数:

(defn myClosureFn []
  (let [stat1 (atom 1)
        stat2 (atom 1)
        ;..stat3 stat4 ...
        ]
    (fn [m]
      (swap! stat1 inc)
      (reset!   stat2 (* 2 m))
      [@stat1  @stat2])))

因此，要获得新鲜状态，您只需调用myClosureFn，它返回一个带有干净计数器的函数。例如:

> (def f1 (myClosureFn))
> (def f2 (myClosureFn))
> (f1 1) ;--> [2 2]
> (f1 2) ;--> [3 4]
> (f2 1) ;--> [2 2]
> (f1 3) ;--> [4 6]

每个函数都带有自己的状态，而不是全局状态。您甚至可以同时创建和使用两个这样的函数，它们不会相互干扰。

Answer 2

您可以使myClosureFn在没有传递参数时充当重置函数

(def myClosureFn 
  (let [stat1 (atom 1)
        stat2 (atom 1)
        ;..stat3 stat4 ...
        ]
    (fn [& [m]]
      (if m
        (do
          (swap! stat1 inc)
          (reset!   stat2 (* 2 m))
          [@stat1  @stat2])
        (do
          (reset! stat1 1)
          (reset! stat2 1))))))

(myClosureFn 1) ;--> [2 2] 
(myClosureFn 2) ;--> [3 4]
(myClosureFn) ;reset to 1 1

或者，如果您正在使用REPL，那么只需在REPL中再次重新评估myClosureFn形式。