如何更改 32 位 TBitmap 中特定颜色的 alpha 值

Question

当像素包含 32 位 TBitmap 的特定颜色时，我需要更改 alpha 组件的值，我知道 ScanLine 属性来访问位图数据，但我无法弄清楚如何更改每个像素的 alpha 分量。

Answer 1

这是一个基本的实现

首先，您需要定义一条记录来保存 ARGB 结构

  TRGB32 = record
    B, G, R, A: byte;
  end;

然后，您必须定义一个 TRGB32 数组来强制转换扫描线并获取和设置值。

检查此示例方法

procedure SetAlphaBitmap(const Dest: TBitmap;Color : TColor;Alpha:Byte);
type
  TRGB32 = record
    B, G, R, A: byte;
  end;
  PRGBArray32 = ^TRGBArray32;
  TRGBArray32 = array[0..0] of TRGB32;
var
  x, y:    integer;
  Line, Delta: integer;
  ColorRGB : TColor;
begin
  if Dest.PixelFormat<>pf32bit then  exit;
  ColorRGB:=ColorToRGB(Color);
  Line  := integer(Dest.ScanLine[0]);
  Delta := integer(Dest.ScanLine[1]) - Line;
  for y := 0 to Dest.Height - 1 do
  begin
    for x := 0 to Dest.Width - 1 do
      if TColor(RGB(PRGBArray32(Line)[x].R, PRGBArray32(Line)[x].G, PRGBArray32(Line)[x].B))=ColorRGB then
        PRGBArray32(Line)[x].A := Alpha;
    Inc(Line, Delta);
  end;
end;

你也可以看看我写的这个单元来操作32位图

Answer 2

对于每 32 位像素，最高字节包含 alpha 值。

var
  P: Cardinal;
  Alpha: Byte;
...
begin
...
  P := bmp.Canvas.Pixels[x, y];         // Read Pixel
  P := P and $00FFFFFF or Alpha shl 24; // combine your desired Alpha with pixel value
  bmp.Canvas.Pixels[x, y] := P;         // Write back
...
end;

Answer 3

我会对 RRUZ 的答案进行以下调整：

procedure SetAlphaBitmap(Dest: TBitmap; Color: TColor; Alpha: Byte); 
type 
  TRGB32 = packed record 
    B, G, R, A: Byte; 
  end; 
  PRGBArray32 = ^TRGBArray32; 
  TRGBArray32 = array[0..0] of TRGB32; 
var 
  x, y: Integer; 
  Line: PRGBArray32; 
  ColorRGB: Longint; 
  Red, Green: Blue: Byte;
begin 
  if Dest.PixelFormat <> pf32bit then Exit; 
  ColorRGB := ColorToRGB(Color); 
  Red := GetRValue(ColorRGB);
  Green := GetGValue(ColorRGB);
  Blue := GetBValue(ColorRGB);
  for y := 0 to Dest.Height - 1 do 
  begin 
    Line := PRGBArray32(Dest.ScanLine[y]);
    for x := 0 to Dest.Width - 1 do
    begin
      with Line[x] do
      begin
        if (R = Red) and (G = Green) and (B = Blue) then 
          A := Alpha; 
      end;
    end;
  end; 
end;