具有分组功能的 XSLT 1.0 计算

Question

我是XSLT的初学者，并使用它通过Java将XML转换为XML。

源 XML：

<Response>
    <Data>
        <Book name="A" value="1"/>
        <Book name="B" value="2"/>
        <Book name="C" value="1"/>
    </Data>
    <Result>
        <Prices>
            <Price type="A" value="100"/>
            <Price type="B" value="60"/>
            <Price type="C" value="40"/>
        </Prices>
    </Result>
</Response>

XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" />
    <xsl:template match="/">
        <xsl:element name="Books">
            <xsl:variable name="BookType" select="//@type" />
            <xsl:attribute name="Total">
                <xsl:value-of select="sum(//Price[@type=$BookType]/@value)"/>
            </xsl:attribute>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

输出 XML：

<Books Total="200"/>

预期输出 XML：

<Books Total="260"/>

在源XML中，我没有收到书及其价格，但它们不相关。

<Price>标签表示一本书的价格。我需要计算所有书籍的总价，如下所示

Price of one book x no of books
For A : 100 x 1 = 100
For B : 60 x 2  = 120
For C : 40 x 1  = 040
------------------------
Total Price is  = 260

请帮忙。

Answer 1

最简单的方法是在包含"price * qty"值的变量中构建一个临时结构，然后使用exslt:node-set扩展函数对这些值求和

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exslt="http://exslt.org/common"
                exclude-result-prefixes="exslt">
  <xsl:output method="xml" indent="yes" />
  <xsl:template match="/">
    <xsl:variable name="subTotals">
      <xsl:for-each select="/Response/Data/Book">
        <totalPrice>
          <xsl:value-of select="@value *
            /Response/Result/Prices/Price[@type = current()/@name]/@value" />
        </totalPrice>
      </xsl:for-each>
    </xsl:variable>
    <Books Total="{sum(exslt:node-set($subTotals)/totalPrice)}" />
  </xsl:template>
</xsl:stylesheet>

可以在

不使用扩展函数的情况下在纯 XSLT 1.0 中执行此操作，但它相当繁琐，并且涉及将累加器参数传递到模板链中：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes" />
  <xsl:template match="/">
    <Books>
      <xsl:apply-templates select="/Response/Data/Book[1]" />
    </Books>
  </xsl:template>
  <xsl:template match="Book">
    <xsl:param name="runningTotal" select="0" />
    <xsl:variable name="thisBookTotal" select="@value *
       /Response/Result/Prices/Price[@type = current()/@name]/@value" />
    <xsl:choose>
      <xsl:when test="following-sibling::Book">
        <!-- There are more books, process the next one, passing an updated
             running total -->
        <xsl:apply-templates select="following-sibling::Book[1]">
          <xsl:with-param name="runningTotal" select="$runningTotal + $thisBookTotal" />
        </xsl:apply-templates>
      </xsl:when>
      <xsl:otherwise>
        <!-- There are no more books, produce the final total -->
        <xsl:attribute name="Total">
          <xsl:value-of select="$runningTotal + $thisBookTotal" />
        </xsl:attribute>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>