XSLT 值未填充在条件中

Question

下面是我正在使用的XML。

<employees>
    <employee>
        <empName>ABC</empName>
        <desgination>SSE</desgination>
        <age></age>
    </employee>
    <employee>
        <empName>DEF</empName>
        <desgination>VP</desgination>
        <age></age>
    </employee>
    <employee>
        <empName>GHI</empName>
        <desgination>Lead</desgination>
        <age></age>
    </employee>        
</employees>

下面是我正在使用的 XSL。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
     xmlns:my="some.uri" version="1.0">
    <my:EMPNames>
        <entry key="ABC">true</entry>
        <entry key="XYZ">true</entry>
        <entry key="JHK">true</entry>        
    </my:EMPNames>
    <xsl:template match="//employee[document('')/*/my:EMPNames/entry[@key = empName]]">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

我无法打印员工姓名为 ABC 的员工部分。我正在使用键值对列表。如果传入的 xml empName 在列表中具有值，我想打印该员工部分。不知何故，我无法获得//employee[document('')/*/my:EMPNames/entry[@key = empName]]的价值，请您告诉我我在这里错过了什么。

Answer 1

表达式 //employee[document('')/*/my:EMPNames/entry[@key = empName]] 的问题是最终的 xpath 谓词entry[@key = empName]。这意味着您正在寻找具有与其子元素 empName 相等的 @key 属性的条目。换句话说，它正在条目元素下查找 empName。

你需要做的是这个。

<xsl:template match="//employee[empName = document('')/*/my:EMPNames/entry/@key]">

或者，如果您只想包含条目为真的那些，请执行此操作

<xsl:template 
    match="//employee[empName = document('')/*/my:EMPNames/entry[. = 'true']/@key]">