我的Tk应用程序在函数中有许多"等待"窗口或暂停，允许其他后台命令有时间完成其工作。问题是在函数中使用"5000 之后"会禁用应用程序中的所有按钮。我找到了很多信息，最有帮助的是 http://wiki.tcl.tk/808。学到的第一个教训是，没有脚本的"之后"不会处理事件循环，第二个是 vwait 是嵌套的。
因此，我使用以下简单的"暂停"函数代替"之后"：
proc pause {ms {waitvar WAITVAR}} {
global $waitvar
after $ms "set $waitvar 1"
puts "waiting $ms for $waitvar"
vwait $waitvar
puts "pause $ms returned"
}
button .b -text PressMe -command {pause 5000 but[incr i]}; # everyone waits on this
pack .b
after 0 {pause 1000 var1}; pause 3000 var2; # works as expected
after 0 {pause 3000 var3}; pause 1000 var4; # both return after 3 secs
我的按钮总是有响应的，但如果按下，所有其他 vwait 至少会再保持 5 秒钟。在 5 秒内第二次按下也会延迟第一次。了解 vwait 是嵌套的，这现在是意料之中的，并没有真正的问题。
这似乎是一个非常简单的解决方案，所以我想得到关于我可能没有的问题的评论。
您已经列出了主要问题，即vwait调用将愉快地嵌套在另一个vwait调用中。（它们是使用对事件循环引擎的递归调用来实现的，因此这是意料之中的。当您得到最终嵌套在自身内部的东西时，这可能是一个特殊的问题;您可以非常轻松地以这种方式炸毁堆栈。解决此问题的传统方法是仔细联锁，例如在处理vwait时禁用调用此特定回调的按钮;这也提供了一种很好的方法来向用户指示您很忙。
另一种方法（您仍然可以在禁用按钮时使用）是分解代码，以便
：proc callback {} {
puts "do some stuff 1"
pause 5000
puts "do some stuff 2"
}
相反，您可以：
proc callback {} {
puts "do some stuff 1"
after 5000 callback2
}
proc callback2 {} {
puts "do some stuff 2"
}
这使您可以避免vwait本身。它被称为延续传递风格编程，在高质量的 Tcl 代码中很常见。不过，这确实有点棘手。考虑这个循环版本：
proc callback {} {
for {set i 1} {$i <= 5} {incr i} {
puts "This is iteration $i"
pause 1000
}
puts "all done"
}
在延续传递风格中，您将执行以下操作：
proc callback {{i 1}} {
if {$i <= 5} {
puts "This is iteration $i"
after 1000 [list callback [incr i]]
} else {
puts "all done"
}
}
您获得的本地状态越多，转换代码就越棘手！
使用 Tcl/Tk 8.6，您有一些额外的技术。
首先，您可以使用coroutine来简化棘手的继续传递内容。
proc callback {} {
coroutine c[incr ::coroutines] apply {{} {
for {set i 1} {$i <= 5} {incr i} {
puts "This is iteration $i"
after 1000 [info coroutine]
yield
}
puts "all done"
}}
}
这有点长，但随着状态的大小和复杂性的增加，这要容易得多。
另一个新的 8.6 工具是 tk busy 命令，它可用于制作方便的模式对话框，在某些操作发生时您无法与之交互（通过带有不可见窗口的巧妙技巧）。仍然由您的代码来确保用户被告知事情很忙，再次通过标记禁用等方式，但tk busy可以使它更容易实现（并且可以帮助避免grab的小棘手问题）。