在 Clojure 中实现向量双循环的惯用方法是什么

Question

我是Clojure的新手，我很难习惯性地实现数据结构的基本操作。

在 Clojure 中实现以下代码的惯用方法是什么？

l = [...]
for i in range(len(l)):
  for j in range(i + 1, len(l)):
    print l[i], l[j]

Answer 1

最简单的(但不是最FP-ish的(与您的示例几乎相同：

(let [v [1 2 3 4 5 6 7]]
  (doseq [i (range (count v))
          j (range (inc i) (count v))]
    (println (v i) (v j))))

这里有更多功能变体来生成所有这些对(它不是基于长度或索引，而是基于尾部迭代(：

(let [v [1 2 3 4 5 6 7]]
  (mapcat #(map (partial vector (first %)) (rest %))
          (take-while not-empty (iterate rest v))))

输出：

 ([1 2] [1 3] [1 4] [1 5] [1 6] [1 7] [2 3] [2 4] 
  [2 5] [2 6] [2 7] [3 4] [3 5] [3 6] [3 7] [4 5] 
  [4 6] [4 7] [5 6] [5 7] [6 7])

然后只需将这些对用于doseq任何副作用：

(let [v [1 2 3 4 5 6 7]
      pairs (fn [items-seq]
              (mapcat #(map (partial vector (first %)) (rest %))
                      (take-while not-empty (iterate rest items-seq))))]
  (doseq [[i1 i2] (pairs v)] (println i1 i2)))

更新：按照@dg123的回答。 这很好，但你可以让它变得更好，使用 doseq 和 for 的功能，如解构和守卫：

(let [v [1 2 3 4 5 6 7]]
  (doseq [[x & xs] (iterate rest v)
          :while xs
          y xs]
    (println "x:" x "y:" y)))

您遍历集合的尾部，但请记住，iterate生成无限的 coll：

user> (take 10 (iterate rest [1 2 3 4 5 6 7]))
([1 2 3 4 5 6 7] (2 3 4 5 6 7) (3 4 5 6 7) 
 (4 5 6 7) (5 6 7) (6 7) (7) () () ())

因此，您必须以某种方式限制它以包含不为空的集合。解构形式[x & xs]将参数拆分为第一个参数和其余参数的序列：

user> (let [[x & xs] [1 2 3 4 5 6]]
        (println x xs))
1 (2 3 4 5 6)
nil

当绑定集合为空或具有单个元素时，xs将nil：

user> (let [[x & xs] [1]]
        (println x xs))
1 nil
nil

因此，您只需使用此功能，在列表理解中使用:while守卫。

最后，您只需为x和xs中的每个项目构建对(或在这种情况下做一些副作用(

Answer 2

如何使用map vector和iterate：

user=> (def l [1 2 3 4 5])
#'user/l
user=> (map vector l (iterate rest (drop 1 l)))
([1 (2 3 4 5)] [2 (3 4 5)] [3 (4 5)] [4 (5)] [5 ()])

这将生成每个i索引的值的延迟序列，后跟其所有j。

然后，您可以使用如下for遍历所需的所有值对：

user=> (for [[i js] (map vector l (iterate rest (drop 1 l))) 
             j js] 
         [i j])
([1 2] [1 3] [1 4] [1 5] [2 3] [2 4] [2 5] [3 4] [3 5] [4 5])

如果要

执行 IO 而不是生成延迟序列，请使用 doseq：

user=> (doseq [[i js] (map vector l (iterate rest (drop 1 l))) 
               j js] 
         (println (str "i: " i " j: " j)))
i: 1 j: 2
i: 1 j: 3
i: 1 j: 4
i: 1 j: 5
i: 2 j: 3
i: 2 j: 4
i: 2 j: 5
i: 3 j: 4
i: 3 j: 5
i: 4 j: 5
nil