vivado 生成的函数 clogb2() 无法合成循环限制错误

Question

我正在尝试用vivado设计一个AXI_master外设。我在 vivado 菜单中使用了 axi 外围生成器并修改了生成的 vhdl 代码。

在 vhdl 代码中，有一个函数 clogb2 声明如下代码：

function clogb2 (bit_depth : integer) return integer is
    variable depth  : integer := bit_depth;
    variable count  : integer := 1;
begin
  for clogb2 in 1 to bit_depth loop  -- Works for up to 32 bit integers
    if (bit_depth <= 2) then
      count := 1;
    else
      if(depth <= 1) then
          count := count;
        else
          depth := depth / 2;
        count := count + 1;
        end if;
    end if;
  end loop;
  return(count);
end;

这在模拟 (GHDL( 中有效，但在合成中失败并出现错误：

[合成器 8-403] 超出循环限制 (65538(

我试图使用以下 tcl 命令增加 vivado 中的循环限制：

set_param synth.elaboration.rodinMoreOptions "rt::set_parameter max_loop_limit <X>"

正如这里所解释的，但 vivado 以无限的时间合成并且永远不会完成。你知道怎么解决这个问题吗？

Answer 1

您也可以尝试其他路径。尽管逻辑不支持浮点数(尽管支持正在增加(，但允许进行内部计算等。(至少由Xilinx和Altera/Intel提供(。

试试这个：

use ieee.math_real.all;
function ceillog2(input : positive) return natural is
begin
    return integer(ceil(log2(real(input))));
end function;

Answer 2

尝试限制输入的范围，例如：

function clogb2 (bit_depth : integer range 1 to 32) return integer is

此外，如果 Vivado 生成的代码无法编译，则应在 Xilinx 论坛上报告此错误。

Answer 3

最后，

我找到了一个解决方案，该解决方案可以通过用大案例重写函数来工作：

function clogb2 (bit_depth : integer) return integer is
 begin
     case bit_depth is
         when 0 to 2             => return( 1);
         when (2** 1)+1 to 2** 2 => return( 2);
         when (2** 2)+1 to 2** 3 => return( 3);
         when (2** 3)+1 to 2** 4 => return( 4);
         when (2** 4)+1 to 2** 5 => return( 5);
         when (2** 5)+1 to 2** 6 => return( 6);
         when (2** 6)+1 to 2** 7 => return( 7);
         when (2** 7)+1 to 2** 8 => return( 8);
         when (2** 8)+1 to 2** 9 => return( 9);
         when (2** 9)+1 to 2**10 => return(10);
         when (2**10)+1 to 2**11 => return(11);
         when (2**11)+1 to 2**12 => return(12);
         when (2**12)+1 to 2**13 => return(13);
         when (2**13)+1 to 2**14 => return(14);
         when (2**14)+1 to 2**15 => return(15);
         when (2**15)+1 to 2**16 => return(16);
         when (2**16)+1 to 2**17 => return(17);
         when (2**17)+1 to 2**18 => return(18);
         when (2**18)+1 to 2**19 => return(19);
         when (2**19)+1 to 2**20 => return(20);
         when (2**20)+1 to 2**21 => return(21);
         when (2**21)+1 to 2**22 => return(22);
         when (2**22)+1 to 2**23 => return(23);
         when (2**23)+1 to 2**24 => return(24);
         when (2**24)+1 to 2**25 => return(25);
         when (2**25)+1 to 2**26 => return(26);
         when (2**26)+1 to 2**27 => return(27);
         when (2**27)+1 to 2**28 => return(28);
         when (2**28)+1 to 2**29 => return(29);
         when (2**29)+1 to 2**30 => return(30);
         when (2**30)+1 to (2**31)-1 => return(31);
         when others => return(0);
     end case;
 end;

有了这种奇怪的代码结构，就可以在合成和模拟中工作。

Answer 4

这个递归版本合成：

function clogb2 (bit_depth : integer) return integer is 
  begin
    if bit_depth <= 1 then
      return 0;
    else
      return clogb2(bit_depth / 2) + 1;
    end if;
  end function clogb2;

您可以使用它来标注其他事物，例如

entity counter is
  generic (max_count : POSITIVE);
  port (clock, reset : in  std_logic;
        Q            : out std_logic_vector(clogb2(max_count) downto 0)  
       );
end;

或者您可以将其用作组合逻辑：

process (I)
begin
  O <= clogb2(I);
end process;

顺便说一句：您最好使用整数子类型进行输入：

function clogb2 (bit_depth : positive) return integer is 
--                               ^
--                               |