您好，我正在尝试将给定的双字数组划分为必须是字节的数组，
a dd 12345678h,1A2B3Ch,78h, ;given array
我只想添加不等于 0 的数字 如您所见，第一个数字没问题，第二个数字末尾有拖曳零 001A2B3Ch，第三个有六个零 00000078h
我写了一个代码来做到这一点，对于第一个数字，它可以添加到 ASCII 代码为 78,56,34,12,28,2B的数组字符中，最后两个数字必须看起来像 (78,56,34,12,3C，2B，1A，78) 我不知道为什么？
assume cs:code, ds:data
data segment
a dd 12345678h,1A2B3Ch,78h ;given array
l equ $-a
l1 equ l/4
zece db 10
pat dw 4
n db l dup(?) ;distination array
data ends
code segment
start:
mov ax,data
mov ds,ax
mov cl,l1
mov ch,0
mov si,0
mov ax,0
mov bx,0
repeta:
mov bx,si
mul pat
mov al,byte ptr a[si]
mov n[bx],al
mov al,byte ptr a[si]+1
add bx,1
mov n[bx],al
mov al,byte ptr a[si]+2
add bx,1
mov n[bx],al
mov al,byte ptr a[si]+3
add bx,1
mov n[bx],al
inc si
loop repeta
mov ax,4C00h
int 21h
code ends
end start
首先，始终了解您的数据，x86 内存可按字节寻址。不管你使用什么样的逻辑结构将数据写入内存，如果其他人正在观看内存内容，并且他们不知道你的逻辑结构，他们只会看到字节。
a dd 12345678h,1A2B3Ch,78h
所以这编译为 12 (3 * 4) 字节：
78 67 34 12 3C 2B 1A 00 78 00 00 00
要通过删除零来压缩这样的数组，您甚至不需要使用双字，只需逐字节复制它(自愿放弃您最初表示为双字数组的知识)，跳过零值。
code segment
start:
mov ax,data
mov ds,ax
lea si,[a] ; original array offset
lea di,[n] ; destination array offset
mov cx,l ; byte (!) length of original array
repeta:
; load single byte from original array
mov al,[si]
inc si
; skip zeroes
test al,al
jz skipping_zero
; store non-zero to destination
mov [di],al
inc di
skipping_zero:
loop repeta
; fill remaining bytes of destination with zeroes - init
xor al,al
lea si,[n+l] ; end() offset of "n"
; jump first to test, so filling is skipped when no zero
jmp fill_remaining_test
fill_remaining_loop:
; clear one more byte in destination
mov [di],al
inc di
fill_remaining_test:
; test if some more bytes are to be cleared
cmp di,si ; current offset < end() offset
jb fill_remaining_loop
; exit back to DOS
mov ax,4C00h
int 21h
code ends
end start
但不幸的是，这是对你的代码的完全重写，所以我将尝试添加一些解释你的错误。
关于MUL，特别是关于乘以两个值的幂：
mov bx,si ; bx = si (index into array?)
mul pat ; dx:ax = ax * word(4)
如您所见，mul不使用bx或si，它导致 32 位值，分为dx(大字)和ax(下字)。
要将si乘以4，您必须执行以下操作之一：
mov ax,si ; ax = si
mul [pat] ; dx:ax = ax * word(4)
或者只是利用计算机正在使用位和整数值的二进制编码，因此要乘以 4，您只需将值中的位值移位"向上"(左)两个位置。
shl si,2 ; si *= 4 (truncated to 16 bit value)
但这会破坏原始si("索引")，因此人们通常不会这样做，而是调整循环增量。您将从si = 0开始，但不是inc si而是add si,4。不再需要乘法。
add bx,1伤害我的眼睛，我更喜欢人类组装中的inc bx(尽管在某些世代的 x86 CPU 上add bx,1更快，但在现代 x86 上inc再次很好)。
mov al,byte ptr a[si]+1语法非常奇怪，我更喜欢保持"类似英特尔"的简单，即。mov al,byte ptr [si + a + 1].它不是 C 数组，它实际上是从括号内的地址从内存中加载值。随着时间的推移，模仿 C 数组语法可能会让您感到困惑。也可以从中删除byte ptr，因为al已经定义了数据宽度(除非您使用一些 MASMdd数组强制执行这一点，但我不想用十英尺的杆子接触微软的东西)。
mov n[bx],al=mov [n + bx],al或mov [bx + n],al也是如此，以代码中更有意义的为准。
但总的来说，在循环中使用索引有点不寻常，通常您希望在 init 部分将所有索引转换为循环前的地址，并使用最终指针而无需在循环内进行任何计算(按元素大小递增它们，即。add si,4双字)。然后，您无需执行任何索引乘法。
特别是在寻址模式非常有限的 16 位模式下，在 32/64b 模式下，您至少可以将一个寄存器与常见大小 (1， 2， 4， 8) 相乘，即。mov [n + ebx * 4],eax= 无需单独相乘。
编辑：在16b模式下没有比例(乘以"索引"部分的1/2/4/8)，可能的示例[si*4]不起作用。
存储来自最高有效dword字节的字节的新变体(即反转x86 dword的小端方案)：
code segment
start:
mov ax,data
mov ds,ax
lea si,[a] ; original array offset
lea di,[n] ; destination array offset
mov cx,l1 ; element-length of original array
repeta:
; load four bytes in MSB-first order from original array
; and store only non-zero bytes to destination
mov al,[si+3]
call storeNonZeroAL
mov al,[si+2]
call storeNonZeroAL
mov al,[si+1]
call storeNonZeroAL
mov al,[si]
call storeNonZeroAL
; advance source pointer to next dword in array
add si,4
loop repeta
; Different ending variant, does NOT zero remaining bytes
; but calculates how many bytes in "n" are set => into CX:
lea cx,[n] ; destination begin() offset
sub cx,di
neg cx ; cx = number of written bytes into "n"
; exit back to DOS
mov ax,4C00h
int 21h
; helper function to store non-zero AL into [di] array
storeNonZeroAL:
test al,al
jz ignoreZeroAL
mov [di],al
inc di
ignoreZeroAL:
ret
code ends
end start
以保持简短和简单的方式编写，而不是为了性能(我强烈建议你以相同的目标为目标，直到你对语言感到非常舒服，即使以简单的方式编写，对于初学者来说也足够困难没有任何专家技巧)。
顺便说一句，您应该找到一些适合您的调试器，因此您可以逐条指令步进并观察"n"中的结果值是如何添加的，以及为什么。或者您可能会更早注意到bx+sivsmul没有执行您期望的操作，并且其余代码在错误的索引上运行。在没有调试器的情况下在汇编中编程就像试图蒙住眼睛组装机器人一样。