更换包装标签并反转

Question

我们有一个遗留系统，它需要一种不是html的格式，但足够接近，令人困惑。在我们闪亮的前端网站上，我们有一个CKEditor的实例，允许用户编辑这种有点像html但不是真正的格式。

最大的区别是我们的格式不理解<p>标签。它希望新行的格式改为<br />。CKEditor可以设置为在BR模式下运行，但也许不足为奇的是，这会导致一些烦人的用户界面错误。

作为替代方案，我正在考虑允许它以默认P模式运行，并用一些 XSLT 替换服务器上的标记。这在一个方向上很容易：

转化：

<root>
<p>Test</p><p>Test</p><p>Test</p>
<p><b>Test</b></p>
</root>

跟：

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
<!-- Replace `[p]contents[/p]` with `contents[br /]` -->
<xsl:template match="p">
    <xsl:apply-templates/><br/>
</xsl:template>

结果：

<root>Test<br/>Test<br/>Test<br/><b>Test</b><br/></root>

问题是，我是否丢失了太多信息，无法反向执行相同的过程？如果没有，解决这个问题的最佳方法是什么？XSLT 甚至是正确的选择吗？

Answer 1

怎么样：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:key name="k1"
  match="root/node()[not(self::br)]" 
  use="generate-id(following-sibling::br[1])"/>
<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="root">
  <xsl:copy>
    <xsl:apply-templates select="br" mode="wrap"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="br" mode="wrap">
  <p>
    <xsl:apply-templates select="key('k1', generate-id())"/>
  </p>
</xsl:template>
</xsl:stylesheet>

使用转换的撒克逊 6.5.5

<root>Test<br/>Test<br/>Test<br/><b>Test</b><br/></root>

到

<root><p>Test</p><p>Test</p><p>Test</p><p><b>Test</b></p></root>