颜色转换为ARGB

Question

我有一个整数值，如-16474153。如何将其转换为ARGB？

在c#中，他使用了颜色函数

Color.FromArgb(buf[buf_pos])

delphi中有没有像上面那样的函数，否则我该如何转换？

我试过这样：

procedure TJP2RenderPreview.put_region(size : _Ckdu_coords; buf : array of Integer; offX, offY : Integer);
var
  x, y          : Integer;
  width, height : Integer;
  buf_pos       : Integer;
  RowPtr        : PRGBQuad;
begin
  width:= size.__property_get_x;
  height:= size.__property_get_y;
  buf_pos:=0;
  for y := offY to offY + height - 1  do
  begin
    RowPtr:= formMain.imgPreview.Bitmap.ScanLine[y];
    Inc(RowPtr, offX);
    for x := 0 to width - 1  do
    begin
      RowPtr.rgbReserved:= (buf[buf_pos] div $1000000);
      RowPtr.rgbRed:= ((buf[buf_pos] mod $1000000) div $10000);
      RowPtr.rgbGreen:= ((buf[buf_pos] mod $10000) div $100);
      RowPtr.rgbBlue:= (buf[buf_pos] mod $100);
      Inc(RowPtr);
      Inc(buf_pos);
    end;
  end;
  formMain.imgPreview.Refresh;
  formMain.imgPreview.Update;
end;

但这不是真的，它看起来是灰色的：/

Answer 1

您的频道似乎混淆了。当您说输入是ARGB时，您将其视为RGBA。在任何情况下，使用div和mod的代码都是无效的。按位转换是惯用的方式。

你可以这样做ARGB输入：

procedure ARGBtoColorChannels(ARGB: DWORD; out A, R, G, B: Byte);
begin
  A := Byte(ARGB);
  R := Byte(ARGB shr 8);
  G := Byte(ARGB shr 16);
  B := Byte(ARGB shr 24);
end;

或者，如果你从RGBA开始，它会变成这样：

procedure RGBAtoColorChannels(RGBA: DWORD; out A, R, G, B: Byte);
begin
  R := Byte(RGBA);
  G := Byte(RGBA shr 8);
  B := Byte(RGBA shr 16);
  A := Byte(RGBA shr 24);
end;

这些都是小端序版本，因为在编写本文时，Delphi只针对小端序机器。

如果你正在寻找一个将ARGB转换为RGBA的函数，那么你可以制作一个这样的函数：

function ARGBtoRGBA(ARGB: DWORD): DWORD;
var
  A, R, G, B: Byte;
begin
  ARGBtoColorChannels(ARGB, A, R, G, B);
  Result := R or (G shl 8) or (B shl 16) or (A shl 24);
end;

为了完整性，反过来是：

function RGBAtoARGB(RGBA: DWORD): DWORD;
var
  A, R, G, B: Byte;
begin
  RGBAtoColorChannels(RGBA, A, R, G, B);
  Result := A or (R shl 8) or (G shl 16) or (B shl 24);
end;

---

为了让你知道该做什么，你需要了解buf是什么。它是ARGB还是RGBA？假设它是ARGB，考虑到您问题的内容，这似乎很可能，您正试图复制到RowPtr，它似乎也是ARGB。在这种情况下，你可以像这样闪电战颜色：

PInteger(RowPtr)^ := buf[buf_pos];

我还强烈建议您更改buf参数的类型。无符号类型在这里更好，因为您可能需要执行逐位操作。更重要的是，通过堆栈复制整个数组，这是非常低效的。对于大型位图，您将遭受堆栈溢出。相反，该参数应该是：

const buf: array of DWORD;

或

const buf: array of Cardinal;

使用const意味着传递对数组的引用，而不是副本。

您还可以避免使用PRGBQuad，并将RowPtr声明为PCardinal类型。

然后你可以这样分配：

RowPtr^ := buf[buf_pos];

在这一点上，你不需要逐个像素地做。您可以使用Move复制整个扫描线，因为这只是一个简单的blit。

for y := offY to offY + height - 1  do
begin
  RowPtr := formMain.imgPreview.Bitmap.ScanLine[y];
  Inc(RowPtr, offX);
  Move(buf[buf_pos], RowPtr^, width*SizeOf(RowPtr^));
  Inc(buf_pos, width);
end;

调用Refresh和Update似乎毫无意义。我不确定你是否也需要打电话，但如果需要，只需打Invalidate！