在Delphi XE中设置运行时的onclick事件

Question

第一次在这里发布，所以请原谅我的礼仪错误。

我在Delphi XE8中创建了一个多设备(FMX)应用程序，并且很难将事件处理程序分配给动态创建的按钮。我搜索了StackOverflow，找到了与NotifyEvents相关的答案，所以我遵循了这些答案中的建议——仍然没有运气。编译错误是"E2010不兼容的类型:'TNotifyEvent'和'Procedure'"。

我已经把一个带有编辑字段和静态Hello按钮的表单的简单测试用例放在一起，第二个按钮创建了一个Goodbye按钮，并试图将一个过程分配给OnClick事件，但我仍然得到相同的错误。

据我所知，我已经遵循了使过程与TNotifyEvent兼容的所有要求，但即使是这个基本示例也会因相同的错误而失败。我的头都撞墙了谁能告诉我我做错了什么吗?

许多谢谢。

unit Dynamic_Button_Test1;
interface
uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls,
  FMX.Controls.Presentation, FMX.Edit;
type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Hello: TButton;
    Create_GoodBye: TButton;
    procedure HelloClick(Sender: TObject);
    procedure Create_GoodByeClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure GoodbyeClick(Sender: TObject) ;
  end;
var
  Form1: TForm1;
implementation
{$R *.fmx}
procedure TForm1.Create_GoodByeClick(Sender: TObject);
var
  New_Button : TButton ;
begin
New_Button := TButton.Create( Form1 );
New_Button.Parent := Form1 ;
New_Button.Text := 'Goodbye' ;
New_Button.Visible := True ;
New_Button.Margins.Left := 50 ;
New_Button.Margins.Right := 50 ;
New_Button.Margins.Bottom := 30 ;
New_Button.Height := 50 ;
New_Button.Align := TAlignLayout.Bottom ;
New_Button.OnClick := TForm1.GoodbyeClick ;
end;
procedure TForm1.HelloClick(Sender: TObject);
begin
Edit1.Text := 'Hello' ;
end;
procedure TForm1.GoodbyeClick(Sender: TObject);
begin
Edit1.Text := 'Goodbye' ;
end;
end.

Answer 1

VCL/FMX事件处理程序在运行时绑定到特定的对象。在分配事件处理程序时，需要用对象指针替换类类型名。当事件稍后被触发时，该对象将是事件处理程序的Self指针:

New_Button.OnClick := Self.GoodbyeClick ;

或者简单地:

New_Button.OnClick := GoodbyeClick ; // Self implicitly used

附带说明-当创建按钮时，该代码是在TForm1实例方法中，所以你应该使用Self对象指针而不是全局Form1对象指针:

New_Button := TButton.Create( Self );
New_Button.Parent := Self ;